{
  config.flake.modules.nixos.quickshell =
    { pkgs, inputs, ... }:
    {
      services.upower.enable = true;
      environment.systemPackages = [
        pkgs.kdePackages.qt5compat
        inputs.quickshell.packages.${pkgs.stdenv.hostPlatform.system}.quickshell
        inputs.qml-niri.packages.${pkgs.stdenv.hostPlatform.system}.qml-niri
      ];
    };
}

{
    "network": {
        "activeInterface": "wlo1",
        "type": 1
    }
}

import QtQuick
import QtQuick.Layouts
import Quickshell
import Quickshell.Wayland
import "./modules/bar/"
import "./modules/common/"
import "./services/"
ShellRoot{
    LazyLoader{
        active: true
        component: Bar{
            position: Types.stringToPosition(Config.data.bar.position)
            size: Config.data.bar.size
            color: Config.data.theme.colors.background
        }
    }
}

pragma Singleton
import QtQuick
import Quickshell
import Quickshell.Io
import qs.modules.common
Singleton {
    // RAM metrics in kibibytes
    property real total: 0.0
    property real used: 0.0
    property real shared: 0.0
    property real buffers: 0.0
    property real cached: 0.0
    property real sreclaimable: 0.0
    property real free: 0.0
    property real available: 0.0
    // Top processes, array of {pid: int, comm: string, mem: float}
    property var topProcesses: []
    signal statsUpdated()
    Process {
        id: psProc
        command: ["sh", "-c", `ps -eo pid,comm,%mem --sort=-%mem --no-headers | head -${Config.data.ram.numTopProcesses+10}`]
        stdout: StdioCollector {
            onStreamFinished: {
                let lines = this.text.split('\n').filter(l => l.trim() !== '');
                let tp = [];
                for (let line of lines) {
                    if (tp.length == Config.data.ram.numTopProcesses) break;
                    let parts = line.trim().split(/\s+/);
                    if (parts.length === 3) {
                        let comm = parts[1];
                        if (comm === 'ps') continue;  // Skip ps itself
                        let pid = parseInt(parts[0]);
                        let mem = parseFloat(parts[2]);
                        tp.push({pid: pid, comm: comm, mem: mem});
                    }
                }
                topProcesses = tp;
            }
        }
    }
    FileView {
        id: meminfoFile
        path: "/proc/meminfo"
        onLoadFailed: function(error) {
            console.log("RAM Service: FileView load failed for /proc/meminfo:", error);
        }
    }
    Timer {
        interval: Config.data.ram.updateInterval
        running: true
        repeat: true
        triggeredOnStart: true
        onTriggered: {
            updateRamStats()
            psProc.running = true
        }
    }
    function updateRamStats() {
        meminfoFile.reload();
        let content = meminfoFile.text();
        if (content === "") return;
        let lines = content.split('\n');
        let stats = {};
        // Parse key lines
        for (let line of lines) {
            let parts = line.split(/\s+/);
            if (parts.length >= 2) {
                let key = parts[0].slice(0, -1);  // Remove colon
                let value = parseFloat(parts[1]);
                stats[key] = value;
            }
        }
        total = stats.MemTotal || 0.0;
        free = stats.MemFree || 0.0;
        buffers = stats.Buffers || 0.0;
        cached = stats.Cached || 0.0;
        shared = stats.Shmem || 0.0;
        available = stats.MemAvailable || (free + buffers + cached);
        sreclaimable = stats.SReclaimable || 0.0;
        used = Math.max(0, total - available);
        statsUpdated()
    }
}

pragma Singleton
import QtQuick
import Niri 0.1
Niri {
    id: niri
    Component.onCompleted: connect()
    onConnected: console.info("Connected to niri")
    onErrorOccurred: function(error) {
        console.error("Niri error:", error)
    }
}

pragma Singleton
import QtQuick
import Quickshell
import Quickshell.Io
import qs.modules.common
Singleton {
    id: root
    // Available interfaces: Map of Types.Network keys to arrays of interface names
    property var interfaces: new Map()
    property string activeInterface: ""
    property int networkType: -1
    // Common
    property real rateUp: 0.0  // Bytes/s
    property real rateDown: 0.0
    property var lanIPs: []  // List of IP strings
    property string wanIP: ""
    // Wireless
    property string ssid: ""
    property int frequency: 0
    property int signalStrength: 0 // dBm
    property real bitrateTx: 0.0  // Mbps
    property real bitrateRx: 0.0  // Mbps
    // Wired
    property int linkSpeed: 0  // Mbps
    // Internal state for rate calculations
    property var tx: 0
    property var rx: 0
    // Fixed 1000ms timer for rates (not configurable, to ensure /s calc)
    Timer {
        id: rateTimer
        interval: 1000
        running: true
        repeat: true
        triggeredOnStart: true
        onTriggered: updateRates()
    }
    // Configurable timers
    Timer {
        id: infoTimer
        interval: Config.data.network.infoUpdateInterval * 1000
        running: true
        repeat: true
        triggeredOnStart: true
        onTriggered: updateInfo()
    }
    Timer {
        id: externalTimer
        interval: Config.data.network.externalUpdateInterval * 1000
        running: true
        repeat: true
        triggeredOnStart: true
        onTriggered: updateExternal()
    }
    FileView {
        id: txBytesView
        path: root.activeInterface ? "/sys/class/net/" + root.activeInterface + "/statistics/tx_bytes" : ""
        preload: false
        onLoadFailed: (error) => console.log("Network Service: Failed to load tx_bytes:", error)
    }
    FileView {
        id: rxBytesView
        path: root.activeInterface ? "/sys/class/net/" + root.activeInterface + "/statistics/rx_bytes" : ""
        preload: false
        onLoadFailed: (error) => console.log("Network Service: Failed to load rx_bytes:", error)
    }
    FileView {
        id: linkSpeedView
        path: root.activeInterface && root.networkType === Types.Network.Wired ? "/sys/class/net/" + root.activeInterface + "/speed" : ""
        preload: false
        onLoadFailed: (error) => console.log("Network Service: Failed to load link speed:", error)
    }
    Process {
        id: listInterfacesProc
        command: [
            "find", "/sys/class/net", "-mindepth", "1", "-maxdepth", "1", "-type", "l",
            "-exec", "sh", "-c", `n=$(basename {}); [ -d {}/wireless ] || [ -L {}/phy80211 ] && echo "$n wireless" || { [ -d {}/device ] && echo "$n wired" || echo "$n virtual"; }`, `\;`
        ]
        stdout: StdioCollector {
            onStreamFinished: {
                const lines = this.text.trim().split('\n');
                const result = new Map([
                    [Types.Network.Wired, []],
                    [Types.Network.Wireless, []],
                    [Types.Network.Virtual, []],
                ]);
                for (const line of lines) {
                    const linet = line.trim();
                    if (linet === '') continue;
                    const [name, itypeStr] = linet.split(/\s+/);
                    const itype = Types.stringToNetwork(itypeStr);
                    result.get(itype).push(name);
                }
                result.forEach(function(val, key, map) {
                    map[key] = val.sort();
                });
                interfaces = result;
            }
        }
        stderr: StdioCollector {
            onStreamFinished: {
                const stderr = this.text.trim();
                if (stderr) {
                    throw new Error(`Failed running listInterfacesProc. Error: ${stderr}`);
                }
            }
        }
        onExited: function(exitCode, exitStatus) {
            if (exitCode !== 0) {
                throw new Error(`Failed running listInterfacesProc. Exit code: ${exitCode}, exit status: ${exitStatus}`);
            }
            autoSelectInterface();
            if (networkType === Types.Network.Wireless) {
                wirelessInfoProc.running = true;
            } else if (networkType === Types.Network.Wired){
                linkSpeedView.reload();
                linkSpeed = parseInt(linkSpeedView.text().trim()) || 0;
            }
            lanIPProc.running = true;
        }
    }
    Process {
        id: lanIPProc
        command: ["ip", "-details", "-json", "address", "show", root.activeInterface]
        stdout: StdioCollector {
            onStreamFinished: {
                try {
                    const data = JSON.parse(this.text);
                    if (data && data.length > 0) {
                        lanIPs = data[0].addr_info ? data[0].addr_info.map(info => info.local).filter(ip => ip) : [];
                    }
                } catch (e) {
                    console.error("Network Service: Failed to parse ip JSON:", e);
                    lanIPs = [];
                }
            }
        }
        stderr: StdioCollector {
            onStreamFinished: {
                const stderr = this.text.trim();
                if (stderr) {
                    throw new Error(`Failed running lanIPProc. Error: ${stderr}`);
                }
            }
        }
        onExited: function(exitCode, exitStatus) {
            if (exitCode !== 0) {
                throw new Error(`Failed running lanIPProc. Exit code: ${exitCode}, exit status: ${exitStatus}`);
            }
        }
    }
    Process {
        id: wirelessInfoProc
        command: ["iw", "dev", root.activeInterface, "link"]
        stdout: StdioCollector {
            onStreamFinished: {
                const lines = this.text.split('\n');
                let ssidFound = "", freqFound = "", rxBitFound = "", txBitFound = "", signalFound = "";
                for (let line of lines) {
                    if (line.includes("SSID:")) ssidFound = line.split("SSID:")[1].trim();
                    if (line.includes("freq:")) freqFound = line.split("freq:")[1].trim();
                    if (line.includes("signal:")) signalFound = line.split("signal:")[1].trim().split(' ')[0];
                    if (line.includes("rx bitrate:")) rxBitFound = line.split("rx bitrate:")[1].trim();
                    if (line.includes("tx bitrate:")) txBitFound = line.split("tx bitrate:")[1].trim();
                }
                ssid = ssidFound;
                frequency = freqFound ? parseInt(freqFound) : 0;
                signalStrength = signalFound ? parseInt(signalFound) : 0;
                bitrateRx = rxBitFound ? parseFloat(rxBitFound) : 0;
                bitrateTx = txBitFound ? parseFloat(txBitFound) : 0;
            }
        }
        stderr: StdioCollector {
            onStreamFinished: {
                const stderr = this.text.trim();
                if (stderr) {
                    throw new Error(`Failed running wirelessInfoProc. Error: ${stderr}`);
                }
            }
        }
        onExited: function(exitCode, exitStatus) {
            if (exitCode !== 0) {
                throw new Error(`Failed running wirelessInfoProc. Exit code: ${exitCode}, exit status: ${exitStatus}`);
            }
        }
    }
    Process {
        id: wanIPProc
        // TODO: Use additional sources to improve robustness.
        command: ["dig", "+short", "@resolver2.opendns.com", "myip.opendns.com"]
        stdout: StdioCollector {
            onStreamFinished: wanIP = this.text.trim() || "N/A"
        }
        stderr: StdioCollector {
            onStreamFinished: {
                const stderr = this.text.trim();
                if (stderr) {
                    throw new Error(`Failed running wanIPProc. Error: ${stderr}`);
                }
            }
        }
        onExited: function(exitCode, exitStatus) {
            if (exitCode !== 0) {
                throw new Error(`Failed running wanIPProc. Exit code: ${exitCode}, exit status: ${exitStatus}`);
            }
        }
    }
    // Public API
    function setActiveInterface(interfaceName, networkType) {
        root.activeInterface = interfaceName;
        root.networkType = networkType;
        resetState();
        updateInfo();
        // Persist the selection
        BarState.data.network.activeInterface = interfaceName;
        BarState.data.network.type = networkType;
    }
    // Internal: Auto-select the most appropriate interface, if none is already
    // selected. Priority order: persisted state, wireless, wired, loopback.
    function autoSelectInterface() {
        if (activeInterface) return;
        // Wait for the state file to be loaded
        BarState.view.waitForJob();
        // Try persisted state first
        const state = BarState.data.network;
        if (state.activeInterface && interfaces.get(state.type)?.includes(state.activeInterface)) {
            activeInterface = state.activeInterface;
            networkType = state.type;
            return;
        }
        let wireless = interfaces.get(Types.Network.Wireless),
            wired = interfaces.get(Types.Network.Wired),
            iface, ifaceType;
        if (wireless?.length) {
            iface = wireless[0];
            ifaceType = Types.Network.Wireless;
        } else if (wired?.length) {
            iface = wired[0];
            ifaceType = Types.Network.Wired;
        } else {
            iface = 'lo';
            ifaceType = Types.Network.Virtual;
        }
        if (iface) {
            activeInterface = iface
            networkType = ifaceType
        }
        // Persist the selection
        state.activeInterface = iface;
        state.type = ifaceType;
    }
    function updateRates() {
        if (!activeInterface) return;
        let prevTx = tx, prevRx = rx;
        rxBytesView.reload();
        rx = parseInt(rxBytesView.text().trim()) || 0;
        txBytesView.reload();
        tx = parseInt(txBytesView.text().trim()) || 0;
        if (prevTx > 0 && prevRx > 0) {  // Skip initial
            rateUp = Math.max(0, tx - prevTx);    // Up = tx (bytes/s)
            rateDown = Math.max(0, rx - prevRx);  // Down = rx
        }
    }
    function updateInfo() {
        listInterfacesProc.running = true;
    }
    function updateExternal() {
        wanIPProc.running = true;
    }
    function resetState() {
        tx = 0; rx = 0; rateUp = 0; rateDown = 0;
        lanIPs = []; ssid = ""; frequency = 0; signalStrength = 0;
        bitrateTx = 0; bitrateRx = 0; linkSpeed = 0;
    }
}

pragma Singleton
import QtQuick
import Quickshell
import Quickshell.Io
import qs.modules.common
Singleton {
    // Array of CPU core usage percentages (0.0 to 1.0), one per core
    property var coreUsages: []
    // Overall CPU usage percentage (0.0 to 1.0), average across all cores
    property real overallUsage: 0.0
    // Previous /proc/stat values for delta calculations
    property var prevStats: []
    // Top processes, array of {pid: int, comm: string, cpu: float}
    property var topProcesses: []
    // Load average values (1-min, 5-min, 15-min)
    property var loadAvg: []
    // Number of top processes to show
    property int numTopProcesses: Config.data.cpu.numTopProcesses || 5
    Process {
        id: psProc
        command: ["sh", "-c", `ps -eo pid,comm,%cpu --sort=-%cpu --no-headers | head -${numTopProcesses+10}`]
        stdout: StdioCollector {
            onStreamFinished: {
                let lines = this.text.split('\n').filter(l => l.trim() !== '');
                let tp = [];
                for (let line of lines) {
                    if (tp.length == numTopProcesses) break;
                    let parts = line.trim().split(/\s+/);
                    if (parts.length === 3) {
                        let comm = parts[1];
                        if (comm === 'ps') continue;  // Skip ps itself
                        let pid = parseInt(parts[0]);
                        let cpu = parseFloat(parts[2]);
                        tp.push({pid: pid, comm: comm, cpu: cpu});
                    }
                }
                topProcesses = tp;
            }
        }
    }
    Process {
        id: loadAvgProc
        command: ["uptime"]
        stdout: StdioCollector {
            onStreamFinished: {
                let line = this.text.trim();
                let parts = line.split("load average:");
                if (parts.length > 1) {
                    let loads = parts[1].trim().split(',').map(s => parseFloat(s.trim()));
                    if (loads.length >= 3) {
                        loadAvg = loads;
                    }
                }
            }
        }
    }
    FileView {
        id: statFile
        path: "/proc/stat"
        onLoadFailed: function(error) {
            console.log("CPU Service: FileView load failed for /proc/stat:", error);
        }
    }
    Timer {
        interval: Config.data.cpu.updateInterval
        running: true
        repeat: true
        triggeredOnStart: true
        onTriggered: {
            updateCpuUsage()
            psProc.running = true
            loadAvgProc.running = true
        }
    }
    function updateCpuUsage() {
        statFile.reload();
        let content = statFile.text();
        if (content === "") {
            return;
        }
        let lines = content.split('\n');
        let currentStats = [];
        // Parse lines starting with "cpu" (cpu, cpu0, cpu1, ...)
        for (let i = 0; i < lines.length; ++i) {
            let line = lines[i].trim();
            if (line.startsWith('cpu')) {
                let parts = line.split(/\s+/);
                if (parts.length >= 8) {
                    let user = parseInt(parts[1]);
                    let nice = parseInt(parts[2]);
                    let system = parseInt(parts[3]);
                    let idle = parseInt(parts[4]);
                    let iowait = parseInt(parts[5]);
                    let irq = parseInt(parts[6]);
                    let softirq = parseInt(parts[7]);
                    // Total ticks: sum of all except idle for denominator
                    let total = user + nice + system + idle + iowait + irq + softirq;
                    currentStats.push({ total: total, idle: idle });
                }
            }
        }
        if (prevStats.length === currentStats.length && prevStats.length > 0) {
            let totalUsage = 0.0;
            let coreUsagesTemp = [];
            // Calculate for each core (skip overall "cpu")
            for (let j = 1; j < currentStats.length; ++j) {
                let current = currentStats[j];
                let prev = prevStats[j];
                let deltaTotal = current.total - prev.total;
                let deltaIdle = current.idle - prev.idle;
                let usage = (deltaTotal > 0) ? (deltaTotal - deltaIdle) / deltaTotal : 0.0;
                usage = Math.min(Math.max(usage, 0.0), 1.0);
                coreUsagesTemp.push(usage);
            }
            // Overall usage
            let overallCurrent = currentStats[0];
            let overallPrev = prevStats[0];
            let overallDeltaTotal = overallCurrent.total - overallPrev.total;
            let overallDeltaIdle = overallCurrent.idle - overallPrev.idle;
            totalUsage = (overallDeltaTotal > 0) ? (overallDeltaTotal - overallDeltaIdle) / overallDeltaTotal : 0.0;
            totalUsage = Math.min(Math.max(totalUsage, 0.0), 1.0);
            coreUsages = coreUsagesTemp;
            overallUsage = totalUsage;
        } else if (prevStats.length === 0) {
            // First run: Store baselines
            prevStats = currentStats;
        }
        prevStats = currentStats;
    }
}

pragma Singleton
import Quickshell
import Quickshell.Services.UPower
import QtQuick
import Quickshell.Io
import qs.services
import qs.modules.common
Singleton {
    property bool available: UPower.displayDevice.isLaptopBattery
    property var chargeState: UPower.displayDevice.state
    property bool isCharging: chargeState == UPowerDeviceState.Charging
    property bool isPluggedIn: isCharging || chargeState == UPowerDeviceState.PendingCharge
    property real percentage: UPower.displayDevice?.percentage ?? 1
    readonly property bool allowAutomaticSuspend: Config.data.battery.automaticSuspend
    property bool isLow: available && (percentage <= Config.data.battery.low / 100)
    property bool isCritical: available && (percentage <= Config.data.battery.critical / 100)
    property bool isSuspending: available && (percentage <= Config.data.battery.suspend / 100)
    property bool isLowAndNotCharging: isLow && !isCharging
    property bool isCriticalAndNotCharging: isCritical && !isCharging
    property bool isSuspendingAndNotCharging: allowAutomaticSuspend && isSuspending && !isCharging
    property real energyRate: UPower.displayDevice.changeRate
    property real timeToEmpty: UPower.displayDevice.timeToEmpty
    property real timeToFull: UPower.displayDevice.timeToFull
    onIsLowAndNotChargingChanged: {
        if (available && isLowAndNotCharging) Quickshell.execDetached([
            "notify-send",
            "Low battery",
            "Consider plugging in your device",
            "-u", "critical",
            "-a", "Shell"
        ])
    }
    onIsCriticalAndNotChargingChanged: {
        if (available && isCriticalAndNotCharging) Quickshell.execDetached([
            "notify-send",
            "Critically low battery",
            "Please charge!\nAutomatic suspend triggers at %1".arg(Config.data.power.battery.suspend),
            "-u", "critical",
            "-a", "Shell"
        ]);
    }
    onIsSuspendingAndNotChargingChanged: {
        if (available && isSuspendingAndNotCharging) {
            Quickshell.execDetached(["sh", "-c", `systemctl suspend || loginctl suspend`]);
        }
    }
}

import QtQuick
Item {
    id: root
    // Public properties
    property color color: "#888888"
    property real strokeSize: 1
    property real length: 100
    property real dashLength: 2
    property real angle: 0  // 0 = horizontal, 90 = vertical (clockwise)
    property string lineType: "solid"  // solid, dotted, dashed, dotdash
    property real edgeRadius: 0  // Radius for line endings and dash caps
    property real spacing: 2  // Spacing multiplier for gaps between dots/dashes
    implicitWidth: Math.abs(Math.cos(angle * Math.PI / 180)) * length +
                   Math.abs(Math.sin(angle * Math.PI / 180)) * strokeSize
    implicitHeight: Math.abs(Math.sin(angle * Math.PI / 180)) * length +
                    Math.abs(Math.cos(angle * Math.PI / 180)) * strokeSize
    Canvas {
        id: canvas
        anchors.fill: parent
        onPaint: {
            const ctx = getContext("2d");
            ctx.reset();
            ctx.save();
            // Translate to center and rotate
            ctx.translate(width / 2, height / 2);
            ctx.rotate(root.angle * Math.PI / 180);
            // Configure line style
            ctx.strokeStyle = root.color;
            ctx.lineWidth = root.strokeSize;
            ctx.lineCap = root.edgeRadius > 0 ? "round" : "butt";
            ctx.lineJoin = "round";
            // Set dash pattern based on line type
            const gap = root.spacing;
            // Dots: very short dash length to create dots
            const dotLength = root.dashLength / 10;
            // Offset to ensure elements aren't cutoff.
            let dashOffset = 0;
            switch(root.lineType) {
                case "dotted":
                    ctx.setLineDash([dotLength, gap]);
                    dashOffset = -root.length / 2 % (gap / 10 + gap);
                    break;
                case "dashed":
                    ctx.setLineDash([root.dashLength, gap]);
                    dashOffset = -root.length / 2 % (dashLength + gap);
                    break;
                case "dotdash":
                    ctx.setLineDash([dotLength, gap, root.dashLength, gap]);
                    dashOffset = -root.length / 2 % (gap / 10 + gap + dashLength + gap);
                    break;
                default:  // solid
                    ctx.setLineDash([]);
            }
            ctx.lineDashOffset = dashOffset;
            // Draw the line
            ctx.beginPath();
            ctx.moveTo(-root.length / 2, 0);
            ctx.lineTo(root.length / 2, 0);
            ctx.stroke();
            // Restore context state
            ctx.restore();
        }
    }
}

import QtQuick
import QtQuick.Shapes
import Quickshell
Item {
    id: root
    property real scale: 1
    property color color: "white"
    width: scale
    height: scale
    // Icon from Phosphor by Phosphor Icons
    // https://github.com/phosphor-icons/core/blob/main/LICENSE
    // Slightly modified to add an additional DRAM chip, and make the chips filled out.
    Shape {
        anchors.centerIn: parent
        width: root.width
        height: root.height
        preferredRendererType: Shape.CurveRenderer
        fillMode: Shape.PreserveAspectFit
        transformOrigin: Item.TopLeft
        ShapePath {
            fillColor: root.color
            strokeColor: "transparent"
            PathSvg { path: "M 232,56 H 24 C 15.163444,56 8,63.163444 8,72 v 128 c 0,4.41828 3.581722,8 8,8 4.418278,0 8,-3.58172 8,-8 v -16 h 16 v 16 c 0,4.41828 3.581722,8 8,8 4.418278,0 8,-3.58172 8,-8 v -16 h 16 v 16 c 0,4.41828 3.581722,8 8,8 4.418278,0 8,-3.58172 8,-8 v -16 h 16 v 16 c 0,4.41828 3.58172,8 8,8 4.41828,0 8,-3.58172 8,-8 v -16 h 16 v 16 c 0,4.41828 3.58172,8 8,8 4.41828,0 8,-3.58172 8,-8 v -16 h 16 v 16 c 0,4.41828 3.58172,8 8,8 4.41828,0 8,-3.58172 8,-8 v -16 h 16 v 16 c 0,4.41828 3.58172,8 8,8 4.41828,0 8,-3.58172 8,-8 v -16 h 16 v 16 c 0,4.41828 3.58172,8 8,8 4.41828,0 8,-3.58172 8,-8 V 72 c 0,-8.836556 -7.16344,-16 -16,-16 M 24,72 h 208 v 96 H 24 Z m 56,80 c 4.41828,0 8,-3.58172 8,-8 V 96 c 0,-4.418278 -3.58172,-8 -8,-8 H 48 c -4.418278,0 -8,3.581722 -8,8 v 48 c 0,4.41828 3.581722,8 8,8 z m 64,0 c 4.41828,0 8,-3.58172 8,-8 V 96 c 0,-4.418278 -3.58172,-8 -8,-8 h -32 c -4.41828,0 -8,3.581722 -8,8 v 48 c 0,4.41828 3.58172,8 8,8 z m 64,0 c 4.41828,0 8,-3.58172 8,-8 V 96 c 0,-4.418278 -3.58172,-8 -8,-8 h -32 c -4.41828,0 -8,3.581722 -8,8 v 48 c 0,4.41828 3.58172,8 8,8 z" }
        }
    }
}

import QtQuick
import QtQuick.Shapes
import qs.modules.common.utils
Item {
    id: root
    property real scale: 1
    property color color: "white"
    // 0 = no bars, 1 = innermost bar only, 2 = two bars, 3 = all three bars
    property int bars: 3
    width: scale
    height: scale
    // Icon from Material Symbols by Google
    // https://github.com/google/material-design-icons/blob/master/LICENSE
    // SVG deconstructed to allow dynamically changing the amount of visible bars.
    Shape {
        anchors.centerIn: parent
        width: root.width
        height: root.height
        preferredRendererType: Shape.CurveRenderer
        fillMode: Shape.PreserveAspectFit
        transformOrigin: Item.TopLeft
        // Innermost bar (opaque when bars >= 1)
        ShapePath {
            fillColor: root.bars >= 1 ? root.color : ColorUtils.transparentize(root.color, 0.75)
            strokeColor: "transparent"
            PathSvg {
                path: "M12 14.5q-.95 0-1.85.25t-1.7.75q-.45.275-.975.263t-.9-.388t-.35-.875t.45-.8q1.175-.825 2.525-1.263T12 12t2.8.438t2.525 1.262q.425.3.45.8t-.35.875t-.9.388t-.975-.263q-.8-.5-1.7-.75T12 14.5"
            }
        }
        // Middle bar (opaque when bars >= 2)
        ShapePath {
            fillColor: root.bars >= 2 ? root.color : ColorUtils.transparentize(root.color, 0.75)
            strokeColor: "transparent"
            PathSvg {
                path: "M12 10.5q-1.75 0-3.375.538T5.6 12.625q-.425.325-.937.313t-.888-.388q-.35-.375-.337-.875t.412-.825q1.75-1.4 3.838-2.125T12.025 8t4.325.725t3.825 2.1q.4.325.425.838t-.35.887t-.9.388t-.95-.313q-1.4-1.05-3.037-1.588T12 10.5"
            }
        }
        // Outermost bar (opaque when bars >= 3)
        ShapePath {
            fillColor: root.bars >= 3 ? root.color : ColorUtils.transparentize(root.color, 0.75)
            strokeColor: "transparent"
            PathSvg {
                path: "M12 6.5q-2.55 0-4.913.85T2.775 9.775q-.425.35-.937.338T.95 9.725t-.362-.887T1 7.975q2.325-1.95 5.15-2.962T12 4t5.85 1.013T23 7.975q.4.35.413.863t-.363.887t-.888.388t-.937-.338Q19.275 8.2 16.913 7.35T12 6.5"
            }
        }
        // Central element (always opaque)
        ShapePath {
            fillColor: root.color
            strokeColor: "transparent"
            PathSvg {
                path: "M12 20q-.825 0-1.412-.587T10 18t.588-1.412T12 16t1.413.588T14 18t-.587 1.413T12 20"
            }
        }
    }
}

import QtQuick
import QtQuick.Shapes
Item {
    id: root
    property real scale: 1
    property color color: "white"
    width: scale
    height: scale
    // Icon from Material Design Icons by Pictogrammers
    // https://github.com/Templarian/MaterialDesign/blob/master/LICENSE
    Shape {
        anchors.centerIn: parent
        width: root.width
        height: root.height
        preferredRendererType: Shape.CurveRenderer
        fillMode: Shape.PreserveAspectFit
        transformOrigin: Item.TopLeft
        ShapePath {
            fillColor: root.color
            strokeColor: "transparent"
            PathSvg { path: "M7 15h2v3h2v-3h2v3h2v-3h2v3h2V9h-4V6H9v3H5v9h2zM4.38 3h15.25A2.37 2.37 0 0 1 22 5.38v14.25A2.37 2.37 0 0 1 19.63 22H4.38A2.37 2.37 0 0 1 2 19.63V5.38C2 4.06 3.06 3 4.38 3" }
        }
    }
}

import QtQuick
import QtQuick.Shapes
Item {
    id: root
    property real scale: 1
    property color color: "white"
    width: scale
    height: scale
    // Icon from Material Design Icons by Pictogrammers
    // https://github.com/Templarian/MaterialDesign/blob/master/LICENSE
    Shape {
        anchors.centerIn: parent
        width: root.width
        height: root.height
        preferredRendererType: Shape.CurveRenderer
        fillMode: Shape.PreserveAspectFit
        transformOrigin: Item.TopLeft
        ShapePath {
            fillColor: root.color
            strokeColor: "transparent"
            PathSvg { path: "M15 20a1 1 0 0 0-1-1h-1v-2h4a2 2 0 0 0 2-2V5a2 2 0 0 0-2-2H7a2 2 0 0 0-2 2v10a2 2 0 0 0 2 2h4v2h-1a1 1 0 0 0-1 1H2v2h7a1 1 0 0 0 1 1h4a1 1 0 0 0 1-1h7v-2zm-8-5V5h10v10zm3-9H8v8h2zm4 0h-3v8h2v-2h1a2 2 0 0 0 2-2V8a2 2 0 0 0-2-2m0 4h-1V8h1z" }
        }
    }
}

import QtQuick
import QtQuick.Shapes
import Quickshell
Item {
    id: root
    property real scale: 1
    property color color: "white"
    width: scale
    height: scale
    // Icon from HeroIcons by Refactoring UI Inc
    // https://github.com/tailwindlabs/heroicons/blob/master/LICENSE
    Shape {
        anchors.centerIn: parent
        width: root.width
        height: root.height
        preferredRendererType: Shape.CurveRenderer
        fillMode: Shape.PreserveAspectFit
        transformOrigin: Item.TopLeft
        ShapePath {
            fillColor: root.color
            strokeColor: "transparent"
            PathSvg { path: "M14 6H6v8h8z" }
        }
        ShapePath {
            fillColor: root.color
            strokeColor: "transparent"
            PathSvg { path: "M9.25 3V1.75a.75.75 0 0 1 1.5 0V3h1.5V1.75a.75.75 0 0 1 1.5 0V3h.5A2.75 2.75 0 0 1 17 5.75v.5h1.25a.75.75 0 0 1 0 1.5H17v1.5h1.25a.75.75 0 0 1 0 1.5H17v1.5h1.25a.75.75 0 0 1 0 1.5H17v.5A2.75 2.75 0 0 1 14.25 17h-.5v1.25a.75.75 0 0 1-1.5 0V17h-1.5v1.25a.75.75 0 0 1-1.5 0V17h-1.5v1.25a.75.75 0 0 1-1.5 0V17h-.5A2.75 2.75 0 0 1 3 14.25v-.5H1.75a.75.75 0 0 1 0-1.5H3v-1.5H1.75a.75.75 0 0 1 0-1.5H3v-1.5H1.75a.75.75 0 0 1 0-1.5H3v-.5A2.75 2.75 0 0 1 5.75 3h.5V1.75a.75.75 0 0 1 1.5 0V3zM4.5 5.75c0-.69.56-1.25 1.25-1.25h8.5c.69 0 1.25.56 1.25 1.25v8.5c0 .69-.56 1.25-1.25 1.25h-8.5c-.69 0-1.25-.56-1.25-1.25z" }
        }
    }
}

import QtQuick
import qs.modules.common
Item {
    id: root
    property color iconColor: "white"
    property int orientation: Types.Orientation.Horizontal
    property real size: 1
    readonly property real borderWidth: size * 0.05
    readonly property real bodyWidth: body.width
    readonly property real bodyHeight: body.height
    readonly property real bodyRadius: body.radius
    state: Types.orientationToString(orientation)
    width: orientation === Types.Orientation.Horizontal ? size : size * 0.6
    height: orientation === Types.Orientation.Vertical ? size : size * 0.6
    Rectangle {
        id: body
        color: "transparent"
        border.color: root.iconColor
        border.width: root.borderWidth
        radius: root.size * 0.1
    }
    Rectangle {
        id: nub
        color: root.iconColor
        radius: 0
    }
    states: [
        State {
            name: "horizontal"
            AnchorChanges {
                target: body
                anchors.left: parent.left
                anchors.right: nub.left
                anchors.verticalCenter: parent.verticalCenter
            }
            AnchorChanges {
                target: nub
                anchors.right: parent.right
                anchors.verticalCenter: parent.verticalCenter
            }
            PropertyChanges {
                target: body
                width: root.width * 0.9
                height: root.height
            }
            PropertyChanges {
                target: nub
                width: root.size * 0.1
                height: root.size * 0.2
                topRightRadius: root.size * 0.1
                bottomRightRadius: root.size * 0.1
            }
        },
        State {
            name: "vertical"
            AnchorChanges {
                target: body
                anchors.left: parent.left
                anchors.right: parent.right
                anchors.top: nub.bottom
                anchors.bottom: parent.bottom
            }
            AnchorChanges {
                target: nub
                anchors.top: parent.top
                anchors.horizontalCenter: parent.horizontalCenter
            }
            PropertyChanges {
                target: body
                width: root.width
                height: root.height * 0.9
            }
            PropertyChanges {
                target: nub
                width: root.size * 0.2
                height: root.size * 0.1
                topLeftRadius: root.size * 0.1
                topRightRadius: root.size * 0.1
            }
        }
    ]
}

import QtQuick
Item {
    id: root
    property real scale: 1
    property color color: "white"
    // Rotation angle (0-360 degrees)
    property real angle: 0
    width: scale
    height: scale
    // Icon from TDesign Icons by TDesign
    // https://github.com/Tencent/tdesign-icons/blob/main/LICENSE
    // Converted to 2D canvas by Grok Code Fast 1.
    // I'm not using the original SVG with Shape since I had issues positioning
    // the rotated icon.
    Canvas {
        anchors.centerIn: parent
        width: root.width
        height: root.height
        onPaint: {
            const ctx = getContext("2d");
            ctx.clearRect(0, 0, width, height);
            ctx.antialiasing = false;
            // Center the canvas coordinate system at the middle of the icon's
            // bounding box
            ctx.save();
            ctx.translate(width / 2, height / 2);
            ctx.rotate(root.angle * Math.PI / 180);
            // Calculate scale to fit the path's implicit bounding box
            // (x:4.5-19.5 = width 15; y:2-22 = height 20) within the canvas
            // bounds
            const pathWidth = 15;  // Implicit bbox width from path
            const pathHeight = 20; // Implicit bbox height from path
            const s = Math.min(width / pathWidth, height / pathHeight);
            ctx.scale(s, s);
            // Translate to offset the path's center (original SVG center at
            // (12,12)) to (0,0) in the centered/rotated space
            ctx.translate(-12, -12);
            // Draw the path
            ctx.fillStyle = root.color;
            ctx.beginPath();
            ctx.moveTo(15, 12);
            ctx.lineTo(19.5, 12);
            ctx.lineTo(12, 2);
            ctx.lineTo(4.5, 12);
            ctx.lineTo(9, 12);
            ctx.lineTo(9, 22);
            ctx.lineTo(15, 22);
            ctx.closePath();
            ctx.fill();
            ctx.restore();
        }
    }
}

import QtQuick
import QtQuick.Controls
import qs.modules.common
import qs.modules.common.utils
/**
 * A progress bar with optional text centered inside it.
 * Partially based on https://github.com/end-4/dots-hyprland/blob/449df7f161e6435569bc7d9499b2e444dd8aa153/dots/.config/quickshell/ii/modules/common/widgets/ClippedProgressBar.qml
 */
ProgressBar {
    id: root
    property int orientation: Types.Orientation.Horizontal
    property real valueBarWidth: 2
    property real valueBarHeight: 1
    property color highlightColor: "gray"
    property color trackColor: ColorUtils.transparentize(highlightColor, 0.7)
    property color textColor: "white"
    property string text
    property bool shimmer: false
    property bool pulse: false
    font.weight: text.length > 2 ? Font.Medium : Font.DemiBold
    background: Item {
        implicitHeight: valueBarHeight
        implicitWidth: valueBarWidth
    }
    contentItem: Rectangle {
        id: contentItem
        anchors.fill: parent
        color: root.trackColor
        SequentialAnimation on color {
            running: root.pulse
            loops: Animation.Infinite
            ColorAnimation {
                from: root.trackColor
                to: {
                    var c = Qt.color(root.trackColor);
                    var boostedLight = Math.min(1.0, c.hslLightness + 0.2);
                    return Qt.hsla(c.hslHue, c.hslSaturation, boostedLight, c.a);
                }
                duration: 1000
                easing.type: Easing.InOutQuad
            }
            ColorAnimation {
                from: {
                    var c = Qt.color(root.trackColor);
                    var boostedLight = Math.min(1.0, c.hslLightness + 0.2);
                    return Qt.hsla(c.hslHue, c.hslSaturation, boostedLight, c.a);
                }
                to: root.trackColor
                duration: 1000
                easing.type: Easing.InOutQuad
            }
        }
        Rectangle {
            id: progressFill
            color: root.highlightColor
            clip: true  // ensure the shimmer is only visible inside progressFill
            anchors {
                top: parent.top
                bottom: parent.bottom
                left: parent.left
                right: undefined
            }
            width: parent.width * root.visualPosition
            height: parent.height
            states: State {
                name: "vertical"
                when: root.orientation === Types.Orientation.Vertical
                AnchorChanges {
                    target: progressFill
                    anchors {
                        top: undefined
                        bottom: parent.bottom
                        left: parent.left
                        right: parent.right
                    }
                }
                PropertyChanges {
                    target: progressFill
                    width: parent.width
                    height: parent.height * root.visualPosition
                }
            }
            Rectangle {
                id: shimmerOverlay
                visible: root.shimmer
                width: root.valueBarWidth
                height: root.valueBarHeight
                property real shimmerWidth: root.orientation === Types.Orientation.Vertical
                                            ? root.valueBarHeight * 0.2 : root.valueBarWidth * 0.2
                x: root.orientation === Types.Orientation.Vertical ? 0 : -progressFill.x
                y: root.orientation === Types.Orientation.Vertical ? -progressFill.y : 0
                opacity: 0.5
                gradient: Gradient {
                    orientation: root.orientation === Types.Orientation.Vertical
                                 ? Gradient.Vertical : Gradient.Horizontal
                    GradientStop { position: -0.3; color: "transparent" }
                    GradientStop {
                        position: Math.max(-0.3,
                                           shimmerAnimation.position - shimmerOverlay.shimmerWidth
                                           / (root.orientation === Types.Orientation.Vertical
                                              ? root.valueBarHeight : root.valueBarWidth))
                        color: "transparent"
                    }
                    GradientStop { position: shimmerAnimation.position; color: "white" }
                    GradientStop {
                        position: Math.min(1.3,
                                           shimmerAnimation.position + shimmerOverlay.shimmerWidth
                                           / (root.orientation === Types.Orientation.Vertical
                                              ? root.valueBarHeight : root.valueBarWidth))
                        color: "transparent"
                    }
                    GradientStop { position: 1.3; color: "transparent" }
                }
                SequentialAnimation on x {
                    id: shimmerAnimation
                    property real position: 0.0
                    running: root.shimmer
                    loops: Animation.Infinite
                    NumberAnimation {
                        target: shimmerAnimation
                        property: "position"
                        from: root.orientation === Types.Orientation.Vertical ? 1.2 : -0.2
                        to: root.orientation === Types.Orientation.Vertical ? 0.8 - value : value + 0.2
                        duration: 3000
                        easing.type: Easing.InOutExpo
                    }
                }
            }
        }
    }
    Text {
        id: overlayText
        font: root.font
        text: root.text
        color: textColor
        opacity: 0.5
        width: root.width
        height: root.height
        verticalAlignment: Text.AlignVCenter
        horizontalAlignment: Text.AlignHCenter
        style: Text.Outline
    }
}

import QtQuick
import QtQuick.Layouts
import QtQuick.Effects
import Quickshell
import Quickshell.Wayland
import qs.modules.common
Item {
    id: root
    property Item hoverTarget
    property int anchorPosition: Types.Position.Top
    property bool shouldShow: false
    // Generic content to display in the popup
    property Component contentComponent: null
    width: hoverTarget ? hoverTarget.width : 0
    height: hoverTarget ? hoverTarget.height : 0
    MouseArea {
        id: mouseArea
        anchors.fill: parent
        hoverEnabled: true
        onEntered: root.onHoveredEntered()
        onExited: root.onHoveredExited()
    }
    Timer {
        id: popupTimer
        interval: 500
        onTriggered: root.open()
    }
    function onHoveredEntered() {
        popupTimer.start()
    }
    function onHoveredExited() {
        popupTimer.stop()
        root.close()
    }
    function open() {
        shouldShow = true
    }
    function close() {
        shouldShow = false
    }
    LazyLoader {
        active: root.shouldShow
        component: PanelWindow {
            id: popupWindow
            color: "transparent"
            anchors {
                left: true
                right: true
                top: root.anchorPosition === Types.Position.Top
                bottom: root.anchorPosition === Types.Position.Bottom
            }
            implicitWidth: contentRect.implicitWidth
            implicitHeight: contentRect.implicitHeight + chevron.height * 2
            margins {
                left: {
                    const mapped = root.QsWindow.mapFromItem(
                        root,
                        (root.width - contentRect.implicitWidth)/2, 0
                    )
                    return mapped.x
                }
                top: root.anchorPosition === Types.Position.Top ? Config.data.bar.size : 0
                bottom: root.anchorPosition === Types.Position.Bottom ? Config.data.bar.size : 0
            }
            exclusionMode: ExclusionMode.Ignore
            exclusiveZone: 0
            WlrLayershell.namespace: "quickshell:hover-popup"
            WlrLayershell.layer: WlrLayer.Top
            Rectangle {
                id: contentRect
                color: Config.data.theme.colors.background
                radius: 8
                implicitWidth: contentLoader.implicitWidth + 24
                implicitHeight: contentLoader.implicitHeight + 24
                y: chevron.height
                layer.enabled: true
                layer.effect: MultiEffect {
                    shadowEnabled: true
                    shadowVerticalOffset: 5
                    shadowHorizontalOffset: 0
                    blurMax: 20
                    shadowColor: "#60000000"
                }
                Loader {
                    id: contentLoader
                    anchors.centerIn: parent
                    sourceComponent: root.contentComponent
                }
            }
            // Chevron element pointing to the hovered component
            Canvas {
                id: chevron
                width: 20
                height: 10
                anchors {
                    horizontalCenter: contentRect.horizontalCenter
                    bottom: root.anchorPosition === Types.Position.Top ? contentRect.top : undefined
                    top: root.anchorPosition === Types.Position.Bottom ? contentRect.bottom : undefined
                }
                onPaint: {
                    var ctx = getContext("2d")
                    ctx.clearRect(0, 0, width, height)
                    ctx.fillStyle = Config.data.theme.colors.background
                    ctx.beginPath()
                    if (root.anchorPosition === Types.Position.Top) {
                        // Pointing up
                        ctx.moveTo(0, height)
                        ctx.lineTo(width / 2, 0)
                        ctx.lineTo(width, height)
                    } else {
                        // Pointing down
                        ctx.moveTo(0, 0)
                        ctx.lineTo(width / 2, height)
                        ctx.lineTo(width, 0)
                    }
                    ctx.closePath()
                    ctx.fill()
                }
            }
        }
    }
}

import QtQuick
import QtQuick.Controls
// A menu that sets its width according to the size of its items, excluding MenuSeparator.
// Source: https://martin.rpdev.net/2018/03/13/qt-quick-controls-2-automatically-set-the-width-of-menus.html
Menu {
    implicitWidth: {
        let result = 0;
        let padding = 0;
        for (let i = 0; i < count; ++i) {
            let item = itemAt(i);
            if (item instanceof MenuItem && !(item instanceof MenuSeparator)) {
                result = Math.max(item.contentItem.implicitWidth, result);
                padding = Math.max(item.padding, padding);
            }
        }
        // Add a small margin factor for the padding.
        return result + padding * 3;
    }
}

pragma Singleton
import Quickshell
Singleton {
    id: root
    // Binary unit factors: 1 KiB = 1024 bytes, etc.
    readonly property int bytesPerKib: 1024
    readonly property int bytesPerMib: 1024 ** 2
    readonly property int bytesPerGib: 1024 ** 3
    readonly property int bytesPerTib: 1024 ** 4
    readonly property int bytesPerPib: 1024 ** 5
    readonly property int bytesPerEib: 1024 ** 6
    // Decimal unit factors: 1 KB = 1000 bytes, etc.
    readonly property int bytesPerKB: 1000
    readonly property int bytesPerMB: 1000 ** 2
    readonly property int bytesPerGB: 1000 ** 3
    readonly property int bytesPerTB: 1000 ** 4
    readonly property int bytesPerPB: 1000 ** 5
    readonly property int bytesPerEB: 1000 ** 6
    // Unit hierarchies
    readonly property var unitsIECByte: ["KiB", "MiB", "GiB", "TiB", "PiB", "EiB"]
    readonly property var unitsMetricByte: ["KB", "MB", "GB", "TB", "PB", "EB"]
    readonly property var unitsIECBit: ["Kib", "Mib", "Gib", "Tib", "Pib", "Eib"]
    readonly property var unitsMetricBit: ["Kb", "Mb", "Gb", "Tb", "Pb", "Eb"]
    readonly property var units: ({
        "B": 1,
        "KB": bytesPerKB,
        "KiB": bytesPerKib,
        "MB": bytesPerMB,
        "MiB": bytesPerMib,
        "GB": bytesPerGB,
        "GiB": bytesPerGib,
        "TB": bytesPerTB,
        "TiB": bytesPerTib,
        "PB": bytesPerPB,
        "PiB": bytesPerPib,
        "EB": bytesPerEB,
        "EiB": bytesPerEib,
        // Bit units (e.g. 1 Kb = 1000 bits = bytesPerKB / 8 bytes)
        "b": 1 / 8.0,
        "Kb": bytesPerKB / 8.0,
        "Kib": bytesPerKib / 8.0,
        "Mb": bytesPerMB / 8.0,
        "Mib": bytesPerMib / 8.0,
        "Gb": bytesPerGB / 8.0,
        "Gib": bytesPerGib / 8.0,
        "Tb": bytesPerTB / 8.0,
        "Tib": bytesPerTib / 8.0,
        "Pb": bytesPerPB / 8.0,
        "Pib": bytesPerPib / 8.0,
        "Eb": bytesPerEB / 8.0,
        "Eib": bytesPerEib / 8.0
    })
    /**
     * Converts a value from one file size unit to another.
     *
     * @param {number} value - The numeric value to convert.
     * @param {string} fromUnit - The unit of the input value (e.g., "KB", "MB").
     * @param {string} toUnit - The unit to convert to (e.g., "MB", "GB").
     * @returns {number} The converted value.
     */
    function convertSizeUnit(value, fromUnit, toUnit) {
        if (!units.hasOwnProperty(fromUnit) || !units.hasOwnProperty(toUnit)) {
            throw new Error("Invalid unit. Supported units: " + Object.keys(units).join(", "));
        }
        if (fromUnit === toUnit) {
            return value;
        }
        var bytes = value * units[fromUnit];
        return bytes / units[toUnit];
    }
    // Determine unit type and return ordered hierarchy.
    function getUnitHierarchy(unit) {
        switch (true) {
        case unit.endsWith('iB'):
            return unitsIECByte;
        case unit.endsWith('B'):
            return unitsMetricByte;
        case unit.endsWith('ib'):
            return unitsIECBit;
        case unit.endsWith('b'):
            return unitsMetricBit;
        default:
            throw new Error(`Invalid unit: ${unit}. Supported units: ` + Object.keys(units).join(", "));
        }
    }
}

pragma Singleton
import Quickshell
/*
  Copied from https://github.com/end-4/dots-hyprland/blob/449df7f161e6435569bc7d9499b2e444dd8aa153/dots/.config/quickshell/ii/modules/common/functions/ColorUtils.qml
*/
Singleton {
    id: root
    /**
     * Returns a color with the hue of color2 and the saturation, value, and alpha of color1.
     *
     * @param {string} color1 - The base color (any Qt.color-compatible string).
     * @param {string} color2 - The color to take hue from.
     * @returns {Qt.rgba} The resulting color.
     */
    function withHueOf(color1, color2) {
        var c1 = Qt.color(color1);
        var c2 = Qt.color(color2);
        // Qt.color hsvHue/hsvSaturation/hsvValue/alpha return 0-1
        var hue = c2.hsvHue;
        var sat = c1.hsvSaturation;
        var val = c1.hsvValue;
        var alpha = c1.a;
        return Qt.hsva(hue, sat, val, alpha);
    }
    /**
     * Returns a color with the saturation of color2 and the hue/value/alpha of color1.
     *
     * @param {string} color1 - The base color (any Qt.color-compatible string).
     * @param {string} color2 - The color to take saturation from.
     * @returns {Qt.rgba} The resulting color.
     */
    function withSaturationOf(color1, color2) {
        var c1 = Qt.color(color1);
        var c2 = Qt.color(color2);
        var hue = c1.hsvHue;
        var sat = c2.hsvSaturation;
        var val = c1.hsvValue;
        var alpha = c1.a;
        return Qt.hsva(hue, sat, val, alpha);
    }
    /**
     * Returns a color with the given lightness and the hue, saturation, and alpha of the input color (using HSL).
     *
     * @param {string} color - The base color (any Qt.color-compatible string).
     * @param {number} lightness - The lightness value to use (0-1).
     * @returns {Qt.rgba} The resulting color.
     */
    function withLightness(color, lightness) {
        var c = Qt.color(color);
        return Qt.hsla(c.hslHue, c.hslSaturation, lightness, c.a);
    }
    /**
     * Returns a color with the lightness of color2 and the hue, saturation, and alpha of color1 (using HSL).
     *
     * @param {string} color1 - The base color (any Qt.color-compatible string).
     * @param {string} color2 - The color to take lightness from.
     * @returns {Qt.rgba} The resulting color.
     */
    function withLightnessOf(color1, color2) {
        var c2 = Qt.color(color2);
        return colorWithLightness(color1, c2.hslLightness);
    }
    /**
     * Adapts color1 to the accent (hue and saturation) of color2 using HSL, keeping lightness and alpha from color1.
     *
     * @param {string} color1 - The base color (any Qt.color-compatible string).
     * @param {string} color2 - The accent color.
     * @returns {Qt.rgba} The resulting color.
     */
    function adaptToAccent(color1, color2) {
        var c1 = Qt.color(color1);
        var c2 = Qt.color(color2);
        var hue = c2.hslHue;
        var sat = c2.hslSaturation;
        var light = c1.hslLightness;
        var alpha = c1.a;
        return Qt.hsla(hue, sat, light, alpha);
    }
    /**
     * Mixes two colors by a given percentage.
     *
     * @param {string} color1 - The first color (any Qt.color-compatible string).
     * @param {string} color2 - The second color.
     * @param {number} percentage - The mix ratio (0-1). 1 = all color1, 0 = all color2.
     * @returns {Qt.rgba} The resulting mixed color.
     */
    function mix(color1, color2, percentage = 0.5) {
        var c1 = Qt.color(color1);
        var c2 = Qt.color(color2);
        return Qt.rgba(percentage * c1.r + (1 - percentage) * c2.r, percentage * c1.g + (1 - percentage) * c2.g, percentage * c1.b + (1 - percentage) * c2.b, percentage * c1.a + (1 - percentage) * c2.a);
    }
    /**
     * Transparentizes a color by a given percentage.
     *
     * @param {string} color - The color (any Qt.color-compatible string).
     * @param {number} percentage - The amount to transparentize (0-1).
     * @returns {Qt.rgba} The resulting color.
     */
    function transparentize(color, percentage = 1) {
        var c = Qt.color(color);
        return Qt.rgba(c.r, c.g, c.b, c.a * (1 - percentage));
    }
    /**
     * Sets the alpha channel of a color.
     *
     * @param {string} color - The base color (any Qt.color-compatible string).
     * @param {number} alpha - The desired alpha (0-1).
     * @returns {Qt.rgba} The resulting color with applied alpha.
     */
    function applyAlpha(color, alpha) {
        var c = Qt.color(color);
        var a = Math.max(0, Math.min(1, alpha));
        return Qt.rgba(c.r, c.g, c.b, a);
    }
}

pragma Singleton
import QtQuick
QtObject {
    enum Orientation {
        Horizontal,
        Vertical
    }
    enum Position {
        Top,
        Bottom
    }
    enum Network {
        Wired,
        Wireless,
        Virtual
    }
    /**
     * I would prefer to use stdlib enum conversion functions:
     * https://doc.qt.io/qt-6/qtqml-typesystem-enumerations.html
     * But these aren't defined in Quickshell v0.2.1, for some reason, even
     * though it does use Qt 6.10...
     */
    function stringToOrientation(str) {
        const normalized = str.toLowerCase();
        switch (normalized) {
        case "horizontal":
            return Types.Orientation.Horizontal;
        case "vertical":
            return Types.Orientation.Vertical;
        default:
            console.error("Error: invalid Orientation value:", str)
            return -1;
        }
    }
    function orientationToString(value) {
        switch (value) {
        case Types.Orientation.Horizontal:
            return "horizontal"
        case Types.Orientation.Vertical:
            return "vertical"
        default:
            console.error("Error: invalid Orientation value:", value)
            return "";
        }
    }
    function stringToPosition(str) {
        const normalized = str.toLowerCase();
        switch (normalized) {
        case "top":
            return Types.Position.Top;
        case "bottom":
            return Types.Position.Bottom;
        default:
            console.error("Error: invalid Position value:", str)
            return -1;
        }
    }
    function positionToString(value) {
        switch (value) {
        case Types.Position.Top:
            return "top"
        case Types.Position.Bottom:
            return "bottom"
        default:
            console.error("Error: invalid Position value:", value)
            return "";
        }
    }
    function stringToNetwork(str) {
        const normalized = str.toLowerCase();
        switch (normalized) {
        case "wired":
            return Types.Network.Wired;
        case "wireless":
            return Types.Network.Wireless;
        case "virtual":
            return Types.Network.Virtual;
        default:
            console.error("Error: invalid Network value:", str)
            return -1;
        }
    }
    function networkToString(value) {
        switch (value) {
        case Types.Network.Wired:
            return "wired"
        case Types.Network.Wireless:
            return "wireless"
        case Types.Network.Virtual:
            return "virtual";
        default:
            console.error("Error: invalid Network value:", value)
            return "";
        }
    }
}

pragma Singleton
import Quickshell
import Quickshell.Io
import qs.modules.common
Singleton {
    property var data: adapter
    FileView {
        path: Quickshell.shellPath("config.json")
        watchChanges: true
        onFileChanged: reload()
        onAdapterUpdated: writeAdapter()
        blockLoading: true
        // For some reason, this is needed to read workspaces.maxCount from the
        // config.json.
        preload: false
        JsonAdapter {
            id: adapter
            // Global theme. Source of default and base values for all components.
            property JsonObject theme: JsonObject {
                property JsonObject colors: JsonObject {
                    property string text: "#999999"
                    property string textMuted: "#777777"
                    property string foreground: "#999999"
                    property string foreground2: "#777777"
                    property string background: "#222222"
                    property string background2: "#666666"
                    property string ok: "#1A7F39"
                    property string error: "#E5002E"
                    property string warning: "#E5BF00"
                }
                // Proportional font
                property JsonObject font: JsonObject {
                    property string family: "Lexend"
                    // Size in pixels of all proportional fonts. The actual size
                    // of fonts in individual components will be proportional to
                    // this value.
                    property real size: 14
                }
                // Monospace font
                property JsonObject fontMono: JsonObject {
                    property string family: "Maple Mono NF"
                    // Size in pixels of all monospace fonts. The actual size of
                    // fonts in individual components will be proportional to
                    // this value.
                    property real size: 14
                }
                property JsonObject widget: JsonObject {
                    // Size in pixels of all widgets. The actual size of
                    // individual widgets will be proportial to this value.
                    property real size: 24
                }
            }
            // Defines the widgets that should be shown in each section and their order.
            property JsonObject layout: JsonObject {
                property JsonObject left: JsonObject {
                    property list<string> widgets: ["workspaces", "focusedWindow"]
                    property bool separator: true
                    property int spacing: 6
                }
                property JsonObject center: JsonObject {
                    property list<string> widgets: []
                    property bool separator: true
                    property int spacing: 6
                }
                property JsonObject right: JsonObject {
                    property list<string> widgets: ["cpu", "ram", "network", "battery", "clock"]
                    property bool separator: true
                    property int spacing: 6
                }
            }
            property JsonObject bar: JsonObject {
                property string position: Types.positionToString(Types.Position.Top)
                property int size: 30
            }
            property JsonObject focusedWindow: JsonObject {
                property JsonObject icon: JsonObject {
                    property bool enabled: true
                    property real scale: 0.9
                }
                property JsonObject title: JsonObject {
                    property bool enabled: true
                }
                property JsonObject font: JsonObject {
                    property string family
                    property real scale: 1.2
                    property int weight: 600
                }
            }
            property JsonObject cpu: JsonObject {
                property real scale: 1
                property real updateInterval: 1000  // Milliseconds
                property int numTopProcesses: 5
                property JsonObject icon: JsonObject {
                    property bool enabled: true
                    property real scale: 0.85
                    property string color: Config.data.theme.colors.foreground2
                }
                property JsonObject graph: JsonObject {
                    property bool enabled: true
                    property real history: 30 // Seconds
                    property string lineColor: Config.data.theme.colors.foreground
                    property string lowUsageColor: "#802D3154"   // Cool blue
                    property string highUsageColor: "#80FF4500"  // Bright orange/red
                }
            }
            property JsonObject ram: JsonObject {
                property real scale: 1
                property real updateInterval: 1000  // Milliseconds
                property string sizeUnit: "GiB"
                property int numTopProcesses: 5
                property JsonObject icon: JsonObject {
                    property bool enabled: true
                    property real scale: 1
                    property string color: Config.data.theme.colors.foreground2
                }
                property JsonObject colors: JsonObject {
                    property string used: "#2E86C1"           // Blue
                    property string shared: "#004880"         // Dark blue
                    property string buffersCached: "#7D3C98"  // Purple
                    property string free: "#666666"           // Gray
                }
                property JsonObject graph: JsonObject {
                    property bool enabled: true
                }
            }
            property JsonObject network: JsonObject {
                property real scale: 1
                // For up/down rates and graph updates
                property real rateUpdateInterval: 1000 // Milliseconds
                // For interface information (link speed, SSID, LAN IPs, etc.)
                property real infoUpdateInterval: 5 // Seconds
                // For external information (WAN IP)
                property real externalUpdateInterval: 600 // Seconds
                property JsonObject rates: JsonObject {
                    property bool enabled: true
                    property string baseUnit: "KiB"
                }
                property JsonObject graph: JsonObject {
                    property bool enabled: true
                    property real history: 30 // Seconds
                }
                property JsonObject icon: JsonObject {
                    property bool enabled: true
                    property real scale: 1
                    property string color: Config.data.theme.colors.foreground2
                }
                property JsonObject colors: JsonObject {
                    property string rx: "#1F77B4"  // Blue
                    property string tx: "#FF7F0E"  // Orange
                }
            }
            property JsonObject battery: JsonObject {
                property real scale: 1.5
                property int low: 20
                property int critical: 10
                property int suspend: 5
                property bool automaticSuspend: true
                property bool showPercentage: true
                property string orientation: Types.orientationToString(Types.Orientation.Horizontal)
            }
            property JsonObject clock: JsonObject {
                property real scale: 1
                property JsonObject time: JsonObject {
                    property bool enabled: true
                    property string format: "hh:mm"
                }
                property JsonObject date: JsonObject {
                    property bool enabled: true
                    property string format: "yyyy-MM-dd"
                }
                property JsonObject font: JsonObject {
                    property string family
                    property real scale: 1
                    property int weight: 400
                }
            }
            property JsonObject workspaces: JsonObject {
                property int maxCount: 10
                property JsonObject icon: JsonObject {
                    property real scale: 0.6
                    property real radius: 1
                }
                property JsonObject colors: JsonObject {
                    property string active: "#000000"
                    property string inactive: "#333333"
                }
            }
        }
    }
}

pragma Singleton
import Quickshell
import Quickshell.Io
Singleton {
    readonly property var data: adapter
    readonly property var view: view
    FileView {
        id: view
        path: Quickshell.shellPath("state.json")
        watchChanges: true
        onFileChanged: reload()
        onAdapterUpdated: writeAdapter()
        blockLoading: true
        JsonAdapter {
            id: adapter
            property JsonObject network: JsonObject {
                property string activeInterface: ""
                property int type: -1
            }
        }
    }
}

import QtQuick
import QtQuick.Layouts
import Quickshell
import qs.modules.common
import qs.services
Rectangle {
    id: root
    implicitWidth: row.width + 20
    implicitHeight: Config.data.bar.size - Config.data.bar.size * 0.25
    color: Config.data.theme.colors.background2
    radius: 50
    Component.onCompleted: {
        Niri.workspaces.maxCount = Config.data.workspaces.maxCount;
    }
    Row {
        id: row
        anchors.centerIn: parent
        spacing: 8
        Repeater {
            model: Niri.workspaces
            Item {
                implicitWidth: 10
                implicitHeight: 10
                Rectangle {
                    anchors.fill: parent
                    radius: 5
                    color: (model.isActive || model.activeWindowId > 0)
                        ? Config.data.workspaces.colors.active
                        : Config.data.workspaces.colors.inactive;
                    opacity: model.isActive ? 1.0 : 0.5
                    scale: model.isActive ? 1.25 : 1.0
                    MouseArea {
                        anchors.fill: parent
                        cursorShape: Qt.PointingHandCursor
                        onClicked: Niri.focusWorkspaceById(model.id)
                    }
                    Behavior on scale {
                        PropertyAnimation {
                            duration: 150
                            easing.type: Easing.InOutQuad
                        }
                    }
                    Behavior on opacity {
                        NumberAnimation { duration: 150 }
                    }
                }
            }
        }
    }
}

import QtQuick
import QtQuick.Layouts
import Quickshell
import qs.modules.common
import qs.modules.common.widgets
import qs.modules.common.utils
import qs.modules.icons
import qs.services
Item {
    id: root
    property real scale: Config.data.ram.scale || 1.0
    implicitWidth: (icon.visible ? icon.width : 0)
        + (graph.visible ? graph.width : 0) + 4
    implicitHeight: Config.data.bar.size - Config.data.bar.size * 0.2
    RAMIcon {
        id: icon
        visible: Config.data.ram.icon.enabled
        color: Config.data.ram.icon.color
        scale: Config.data.ram.icon.scale * root.height
        anchors.verticalCenter: parent.verticalCenter
    }
    Canvas {
        id: graph
        visible: Config.data.ram.graph.enabled
        anchors {
            top: parent.top
            bottom: parent.bottom
            right: parent.right
        }
        width: 100 * root.scale
        onPaint: {
            if (RAM.total === 0) return;
            let ctx = getContext("2d");
            ctx.clearRect(0, 0, width, height);
            let usedRatio = RAM.used / RAM.total;
            let sharedRatio = RAM.shared / RAM.total;
            let buffersCachedRatio = (RAM.buffers + RAM.cached + RAM.sreclaimable) / RAM.total;
            let freeRatio = RAM.free / RAM.total;
            // Clamp small ratios to minimum visible width
            let minVisible = 1 / width;
            usedRatio = Math.max(usedRatio, minVisible);
            sharedRatio = Math.max(sharedRatio, minVisible);
            buffersCachedRatio = Math.max(buffersCachedRatio, minVisible);
            freeRatio = Math.max(freeRatio, minVisible);
            let cumulativeX = 0;
            // Draw segments from left to right
            if (usedRatio > 0) {
                ctx.fillStyle = Config.data.ram.colors.used;
                ctx.fillRect(cumulativeX, 0, usedRatio * width, height);
                cumulativeX += usedRatio * width;
            }
            if (sharedRatio > 0) {
                ctx.fillStyle = Config.data.ram.colors.shared;
                ctx.fillRect(cumulativeX, 0, sharedRatio * width, height);
                cumulativeX += sharedRatio * width;
            }
            if (buffersCachedRatio > 0) {
                ctx.fillStyle = Config.data.ram.colors.buffersCached;
                ctx.fillRect(cumulativeX, 0, buffersCachedRatio * width, height);
                cumulativeX += buffersCachedRatio * width;
            }
            if (freeRatio > 0) {
                ctx.fillStyle = Config.data.ram.colors.free;
                ctx.fillRect(cumulativeX, 0, freeRatio * width, height);
            }
        }
    }
    Connections {
        target: RAM
        function onStatsUpdated() {
            graph.requestPaint()
        }
    }
    HoverPopup {
        anchors.centerIn: root
        hoverTarget: root
        anchorPosition: Types.stringToPosition(Config.data.bar.position)
        contentComponent: Component {
            ColumnLayout {
                id: contentColumn
                spacing: 2
                Text {
                    Layout.alignment: Qt.AlignHCenter
                    text: "RAM Usage"
                    font.family: Config.data.theme.font.family
                    font.pixelSize: Config.data.theme.font.size
                    font.bold: true
                    color: Config.data.theme.colors.foreground
                }
                Text {
                    Layout.alignment: Qt.AlignHCenter
                    font.family: Config.data.theme.font.family
                    font.pixelSize: Config.data.theme.font.size
                    color: Config.data.theme.colors.foreground
                    textFormat: Text.RichText
                    text: {
                        let rows = [
                            {
                                label: "Total",
                                source: ['total'],
                                color: Config.data.theme.colors.foreground,
                            },
                            {
                                label: "Used",
                                source: ['used'],
                                color: Config.data.ram.colors.used,
                            },
                            {
                                label: "Shared",
                                source: ['shared'],
                                color: Config.data.ram.colors.shared,
                            },
                            {
                                label: "Buff/Cache",
                                source: ['buffers', 'cached', 'sreclaimable'],
                                color: Config.data.ram.colors.buffersCached,
                            },
                            {
                                label: "Free",
                                source: ['free'],
                                color: Config.data.ram.colors.free,
                            },
                            {
                                label: "Available",
                                source: ['available'],
                                color: Config.data.theme.colors.foreground,
                            },
                        ];
                        let total = FileUtils.convertSizeUnit(RAM.total, "KiB", Config.data.ram.sizeUnit);
                        for (let i = 0; i < rows.length; ++i) {
                            let val = 0.0;
                            for (let j = 0; j < rows[i].source.length; ++j) {
                                val += RAM[rows[i].source[j]];
                            }
                            if (rows[i].label === 'Total') {
                                rows[i].value = total;
                            } else {
                                rows[i].value = FileUtils.convertSizeUnit(val, "KiB", Config.data.ram.sizeUnit);
                                rows[i].pct = (rows[i].value / total)*100;
                            }
                        }
                        let createRow = function(rowData) {
                            return `
<tr>
  <td align="left" width="60"><span style="color: ${rowData.color}">${rowData.label}</span>:</td>
  <td align="right" width="70"><span style="font-family: '${Config.data.theme.fontMono.family}'; font-size: ${Config.data.theme.fontMono.size}px;">${rowData.value.toFixed(2)}${Config.data.ram.sizeUnit}</span></td>
  <td align="right" width="60"><span style="font-family: '${Config.data.theme.fontMono.family}'; font-size: ${Config.data.theme.fontMono.size}px;">${typeof rowData.pct !== 'undefined' ? rowData.pct.toFixed(2) + "%" : ""}</span></td>
</tr>`;
                        };
                        return `<table>${rows.map(r => createRow(r)).join("")}</table>`;
                    }
                }
                Text {
                    Layout.alignment: Qt.AlignHCenter
                    text: "Top Processes"
                    font.family: Config.data.theme.font.family
                    font.pixelSize: Config.data.theme.font.size
                    font.bold: true
                    color: Config.data.theme.colors.foreground
                    Layout.topMargin: 6
                }
                Text {
                    Layout.alignment: Qt.AlignHCenter
                    font.family: Config.data.theme.fontMono.family
                    font.pixelSize: Config.data.theme.fontMono.size
                    color: Config.data.theme.colors.foreground
                    text: {
                        let out = [];
                        for (let p of RAM.topProcesses) {
                            let pidStr = p.pid.toString().padStart(6);
                            let commStr = p.comm.slice(0, 15).padEnd(15);
                            let memStr = `${p.mem.toFixed(1)}%`;
                            out.push(`${pidStr} ${commStr}\t${memStr.padStart(6)}`);
                        }
                        return out.join("\n");
                    }
                }
            }
        }
    }
}

import QtQuick
import QtQuick.Controls
import QtQuick.Layouts
import qs.modules.common
import qs.modules.common.utils
import qs.modules.common.widgets
import qs.modules.icons
import qs.services
Item {
    id: root
    property real scale: Config.data.network.scale
    property real history: Config.data.network.graph.history
    property var points: []  // Graph points: [{x: time, up: bytes/s, down: bytes/s}]
    readonly property var unitHierarchy: FileUtils.getUnitHierarchy(Config.data.network.rates.baseUnit)
    implicitWidth: (graph.visible ? graph.width : 0)
        + (iconLoader.visible ? iconLoader.width : 0)
        + (rates.visible ? rates.width : 0) + 4
    implicitHeight: Config.data.bar.size - Config.data.bar.size * 0.2
    Component.onCompleted: points.push({x: Date.now(), up: 0, down: 0});
    Timer {
        interval: Config.data.network.rateUpdateInterval
        running: true
        repeat: true
        onTriggered: {
            const x = Date.now(), up = Network.rateUp, down = Network.rateDown;
            points.push({x, up, down});
            const cutoff = x - history * 1000;
            while (points.length && points[0].x < cutoff) points.shift();
            graph.requestPaint();
        }
    }
    Loader {
        id: iconLoader
        visible: Config.data.network.icon.enabled
        width: sourceComponent.width
        height: sourceComponent.height
        anchors.verticalCenter: parent.verticalCenter
        sourceComponent: Network.networkType === Types.Network.Wireless ?
                         wirelessIcon :
                         (Network.networkType === Types.Network.Wired ? wiredIcon : virtualIcon)
    }
    Component {
        id: wiredIcon
        NetworkWiredIcon {
            color: Config.data.network.icon.color
            scale: Config.data.network.icon.scale * root.height
            anchors.verticalCenter: parent.verticalCenter
        }
    }
    Component {
        id: wirelessIcon
        NetworkWirelessIcon {
            color: Config.data.network.icon.color
            scale: Config.data.network.icon.scale * root.height
            anchors.verticalCenter: parent.verticalCenter
            bars: {
                const thresholds = [-60, -70, -80, -90];
                let numBars = 3;
                for (let i=0; i < thresholds.length; ++i) {
                    if (Network.signalStrength > thresholds[i]) break;
                    numBars--;
                }
                return Math.max(numBars, 0);
            }
        }
    }
    Component {
        id: virtualIcon
        NetworkVirtualIcon {
            color: Config.data.network.icon.color
            scale: Config.data.network.icon.scale * root.height
            anchors.verticalCenter: parent.verticalCenter
        }
    }
    Canvas {
        id: graph
        visible: Config.data.network.graph.enabled
        anchors {
            top: parent.top
            bottom: parent.bottom
            left: iconLoader.right
            leftMargin: iconLoader.visible ? 2 : 0
        }
        implicitWidth: visible ? 100 * root.scale : 0
        onPaint: {
            const ctx = getContext("2d");
            ctx.clearRect(0, 0, width, height);
            if (points.length < 2) return;
            const range = history * 1000, currentTime = Date.now(), minTime = currentTime - range;
            const visiblePoints = points.filter(p => p.x >= minTime);
            const margin = 2, marginHeight = height - 2 * margin;
            const drawLine = function(prop, color) {
                ctx.strokeStyle = color;
                ctx.beginPath();
                for (let i = 0; i < visiblePoints.length; ++i) {
                    const px = ((visiblePoints[i].x - minTime) / range) * width;
                    const py = margin + (1 - visiblePoints[i][prop] / maxRate) * marginHeight;
                    if (i === 0) ctx.moveTo(px, py);
                    ctx.lineTo(px, py);
                }
                ctx.stroke();
            }
            ctx.lineWidth = 2;
            drawLine('up', Config.data.network.colors.tx);
            drawLine('down', Config.data.network.colors.rx)
        }
        property real maxRate: 1  // Computed: max of all up/down points, updated on paint
        onPainted: { maxRate = Math.max(...points.map(p => Math.max(p.up, p.down)), 1); }
    }
    // Return the rate value using the most appropriate unit within the given
    // hierarchy, starting with the given base unit.
    // This ensures that the rate component never displays more than 5 digits,
    // so that it can have a predictable max width.
    function getDisplayRate(rateBytes, fromUnit, baseUnit, hierarchy) {
        const startIndex = Math.max(0, hierarchy.indexOf(baseUnit));
        for (let i = startIndex; i < hierarchy.length; i++) {
            const unit = hierarchy[i];
            const rate = FileUtils.convertSizeUnit(rateBytes, fromUnit, unit);
            // Use this unit if rate fits OR it's the last available unit
            if (rate < 1000 || i === hierarchy.length - 1) {
                return {unit, rate};
            }
        }
        // Fallback to largest unit. Shouldn't happen...
        const lastUnit = hierarchy[hierarchy.length - 1];
        return {
            unit: lastUnit,
            rate: FileUtils.convertSizeUnit(rateBytes, fromUnit, lastUnit)
        };
    }
    ColumnLayout {
        id: rates
        visible: Config.data.network.rates.enabled
        spacing: -4
        anchors {
            left: graph.right
            leftMargin: 4
            verticalCenter: parent.verticalCenter
        }
        // Calculate fixed width based on maximum possible text
        TextMetrics {
            id: rateTextMetrics
            // The "M" in "MiB", "MB", etc. is usually the widest font glyph.
            text: "999.99 " + root.unitHierarchy[1] + "/s"
            font.family: Config.data.theme.font.family
            font.pixelSize: Config.data.theme.font.size * 0.9
        }
        RowLayout {
            spacing: 2
            ArrowIcon {
                id: txArrowIcon
                scale: root.height / 2
                angle: 0
                color: Config.data.network.colors.tx
            }
            Text {
                text: {
                    const display = getDisplayRate(Network.rateUp, 'B', Config.data.network.rates.baseUnit, root.unitHierarchy);
                    return `${display.rate.toFixed(2)} ${display.unit}/s`;
                }
                font.family: Config.data.theme.font.family
                font.pixelSize: Config.data.theme.font.size * 0.9
                color: Config.data.network.colors.tx
                Layout.preferredWidth: rateTextMetrics.width
                horizontalAlignment: Text.AlignRight
            }
        }
        RowLayout {
            spacing: 2
            ArrowIcon {
                id: rxArrowIcon
                scale: root.height / 2
                angle: 180
                color: Config.data.network.colors.rx
            }
            Text {
                text: {
                    const display = getDisplayRate(Network.rateDown, 'B', Config.data.network.rates.baseUnit, root.unitHierarchy);
                    return `${display.rate.toFixed(2)} ${display.unit}/s`;
                }
                font.family: Config.data.theme.font.family
                font.pixelSize: Config.data.theme.font.size * 0.9
                color: Config.data.network.colors.rx
                Layout.preferredWidth: rateTextMetrics.width
                horizontalAlignment: Text.AlignRight
            }
        }
    }
    MouseArea {
        anchors.fill: parent
        acceptedButtons: Qt.RightButton | Qt.LeftButton
        onClicked: (mouse) => (mouse.button === Qt.RightButton) && menu.popup()
    }
    AutoSizingMenu {
        id: menu
        popupType: Popup.Native
        title: "Available Interfaces"
        closePolicy: Popup.CloseOnEscape | Popup.CloseOnPressOutside | Popup.CloseOnPressOutsideParent
        AutoSizingMenu {
            title: "Select interface"
            // Group 1: Wireless
            Repeater {
                model: Network.interfaces.get(Types.Network.Wireless)
                MenuItem {
                    contentItem: Row {
                        spacing: 4
                        anchors.verticalCenter: parent.verticalCenter
                        Loader {
                            active: true
                            sourceComponent: wirelessIcon
                            onLoaded: {
                                item.color = ColorUtils.withLightness(palette.windowText, 0.4);
                                item.scale = 16;
                                item.bars = 3;
                            }
                        }
                        Text {
                            text: modelData
                            color: palette.windowText
                            font.pixelSize: Config.data.theme.font.size * 0.9
                        }
                    }
                    onTriggered: {
                        Network.setActiveInterface(modelData, Types.Network.Wireless);
                        points = [];
                    }
                }
            }
            // Separator after wireless group (only if wireless AND wired OR
            // virtual groups are not empty).
            // A Repeater must be used for the separator to be placed dynamically.
            Repeater {
                model: Network.interfaces.get(Types.Network.Wireless)?.length > 0
                    && (Network.interfaces.get(Types.Network.Wired)?.length > 0
                        || Network.interfaces.get(Types.Network.Virtual)?.length > 0)
                    ? [1] : []
                delegate: MenuSeparator {}
            }
            // Group 2: Wired
            Repeater {
                model: Network.interfaces.get(Types.Network.Wired)
                MenuItem {
                    contentItem: Row {
                        spacing: 4
                        anchors.verticalCenter: parent.verticalCenter
                        Loader {
                            active: true
                            sourceComponent: wiredIcon
                            onLoaded: {
                                item.color = ColorUtils.withLightness(palette.windowText, 0.4);
                                item.scale = 16;
                            }
                        }
                        Text {
                            text: modelData
                            color: palette.windowText
                            font.pixelSize: Config.data.theme.font.size * 0.9
                        }
                    }
                    onTriggered: {
                        Network.setActiveInterface(modelData, Types.Network.Wired);
                        points = [];
                    }
                }
            }
            // Separator after wired group (only if wired AND virtual groups are
            // not empty).
            // A Repeater must be used for the separator to be placed dynamically.
            Repeater {
                model: Network.interfaces.get(Types.Network.Wired)?.length > 0
                    && Network.interfaces.get(Types.Network.Virtual)?.length > 0
                    ? [1] : []
                delegate: MenuSeparator {}
            }
            // Group 3: Virtual
            Repeater {
                model: Network.interfaces.get(Types.Network.Virtual)
                MenuItem {
                    contentItem: Row {
                        spacing: 4
                        anchors.verticalCenter: parent.verticalCenter
                        Loader {
                            active: true
                            sourceComponent: virtualIcon
                            onLoaded: {
                                item.color = ColorUtils.withLightness(palette.windowText, 0.4);
                                item.scale = 16;
                            }
                        }
                        Text {
                            text: modelData
                            color: palette.windowText
                            font.pixelSize: Config.data.theme.font.size * 0.9
                        }
                    }
                    onTriggered: {
                        Network.setActiveInterface(modelData, Types.Network.Virtual);
                        points = [];
                    }
                }
            }
        }
    }
    HoverPopup {
        anchors.centerIn: root
        hoverTarget: root
        anchorPosition: Types.stringToPosition(Config.data.bar.position)
        contentComponent: Component {
            ColumnLayout {
                id: contentColumn
                spacing: 2
                Text {
                    Layout.alignment: Qt.AlignHCenter
                    text: `Interface: ${Network.activeInterface} (${Types.networkToString(Network.networkType)})`
                    font.family: Config.data.theme.font.family
                    font.pixelSize: Config.data.theme.font.size
                    font.bold: true
                    color: Config.data.theme.colors.foreground
                }
                Text {
                    Layout.alignment: Qt.AlignHCenter
                    font.family: Config.data.theme.font.family
                    font.pixelSize: Config.data.theme.font.size
                    color: Config.data.theme.colors.foreground
                    textFormat: Text.RichText
                    text: {
                        let rows = [
                            {
                                label: "LAN IPs",
                                value: Network.lanIPs.length ? Network.lanIPs.join("<br>") : "N/A",
                                font: Config.data.theme.fontMono.family,
                                fontSize: Config.data.theme.fontMono.size,
                            },
                            {
                                label: "WAN IP",
                                value: Network.wanIP || "N/A",
                                font: Config.data.theme.fontMono.family,
                                fontSize: Config.data.theme.fontMono.size,
                            },
                        ];
                        switch (Network.networkType) {
                        case Types.Network.Wireless:
                            rows = [
                                {
                                    label: "SSID",
                                    value: Network.ssid || "N/A",
                                    font: Config.data.theme.font.family,
                                    fontSize: Config.data.theme.font.size,
                                },
                                {
                                    label: "Signal",
                                    value: Network.signalStrength < 0 ? Network.signalStrength + " dBm" : "N/A",
                                    font: Config.data.theme.font.family,
                                    fontSize: Config.data.theme.font.size,
                                },
                                {
                                    label: "Bitrate",
                                    value: function() {
                                        let out = [];
                                        if (Network.bitrateRx > 0) {
                                            let rx = getDisplayRate(Network.bitrateRx, 'Mb', 'Mb', FileUtils.unitsMetricBit);
                                            out.push(`↓ ${rx.rate} ${rx.unit}/s`);
                                        }
                                        if (Network.bitrateTx > 0) {
                                            let tx = getDisplayRate(Network.bitrateTx, 'Mb', 'Mb', FileUtils.unitsMetricBit);
                                            out.push(`↑ ${tx.rate} ${tx.unit}/s`);
                                        }
                                        if (out.length) {
                                            return out.join("<br>");
                                        }
                                        return "N/A";
                                    }(),
                                    font: Config.data.theme.font.family,
                                    fontSize: Config.data.theme.font.size,
                                },
                            ].concat(rows);
                            break;
                        case Types.Network.Wired:
                            rows = [
                                {
                                    label: "Link speed",
                                    value: function() {
                                        if (Network.linkSpeed > 0) {
                                            let dr = getDisplayRate(Network.linkSpeed, 'Mb', 'Mb', FileUtils.unitsMetricBit);
                                            return `${dr.rate} ${dr.unit}/s`;
                                        }
                                        return "N/A";
                                    }(),
                                    font: Config.data.theme.font.family,
                                    fontSize: Config.data.theme.font.size,
                                },
                            ].concat(rows);
                            break;
                        }
                        let createRow = function(rowData) {
                            return `
<tr>
  <td align="left" width="60">${rowData.label}:</td>
  <td align="left" width="150"><span style="font-family: '${rowData.font}'; font-size: ${rowData.fontSize}px;">${rowData.value}</span></td>
</tr>`;
                        };
                        return `<table>${rows.map(r => createRow(r)).join("")}</table>`;
                    }
                }
            }
        }
    }
}

import QtQuick
import QtQuick.Layouts
import Quickshell
import qs.modules.common
RowLayout {
    id: root
    required property string section
    property var widgetComponents
    spacing: Config.data.layout[section]?.spacing || 0
    readonly property var widgetModel: {
        let model = [];
        let hasPreviousWidget = false;
        const widgets = Config.data.layout[section]?.widgets || [];
        const useSeparator = Config.data.layout[section]?.separator || false;
        for (let i = 0; i < widgets.length; i++) {
            const widget = widgetComponents[widgets[i]];
            if (!widget) {
                console.error(`invalid widget: ${widgets[i]}`);
                continue;
            }
            if (useSeparator && hasPreviousWidget) {
                model.push(widgetComponents["separator"]);
            }
            model.push(widget);
            hasPreviousWidget = true;
        }
        return model;
    }
    Repeater {
        model: root.widgetModel
        delegate: Loader {
            active: true
            sourceComponent: modelData
        }
    }
}

import QtQuick
import qs.modules.common
import qs.services
Row {
    spacing: 4
    Image {
        anchors.verticalCenter: parent.verticalCenter
        source: Niri.focusedWindow?.iconPath ? "file://" + Niri.focusedWindow?.iconPath : ""
        sourceSize.width: Config.data.focusedWindow.icon.scale * Config.data.theme.widget.size
        sourceSize.height: Config.data.focusedWindow.icon.scale * Config.data.theme.widget.size
        visible: Config.data.focusedWindow.icon.enabled && Niri.focusedWindow?.iconPath !== ""
        smooth: true
    }
    // Fallback for missing icons
    Rectangle {
        anchors.verticalCenter: parent.verticalCenter
        width: Config.data.focusedWindow.icon.scale * Config.data.theme.widget.size
        height: Config.data.focusedWindow.icon.scale * Config.data.theme.widget.size
        color: "#CCC"
        visible: Config.data.focusedWindow.icon.enabled && Niri.focusedWindow?.iconPath === ""
        radius: 12
    }
    Text {
        // FIXME: Make the width proportional to the width of the container.
        width: 1000
        elide: Text.ElideRight
        anchors.verticalCenter: parent.verticalCenter
        text: Niri.focusedWindow?.title ?? ""
        font.family: Config.data.focusedWindow.font.family || Config.data.theme.font.family
        font.pixelSize: Config.data.focusedWindow.font.scale * Config.data.theme.font.size
        font.weight: Config.data.focusedWindow.font.weight
        color: Config.data.theme.colors.text
        visible: Config.data.focusedWindow.title.enabled
    }
}

import QtQuick
import QtQuick.Layouts
import Quickshell
import qs.modules.common
// Clock component that displays time and date in a vertically stacked
// layout, with both blocks horizontally centered along the same axis. The width
// and height of the blocks is dynamically determined to avoid layout shifting
// with proportional fonts as digits change, and to make the shorter block
// slightly larger to compensate.
Item {
    id: root
    property real size: 1
    SystemClock {
        id: clock
        precision: SystemClock.Seconds
    }
    implicitWidth: contentItem.implicitWidth
    implicitHeight: size
    // Fixed-width blocks used as width references for the actual time and date blocks.
    // The reference isn't perfect, but should look good in most cases.
    TextMetrics {
        id: timeMetrics
        font: timeBlock.font
        text: Qt.formatDateTime(new Date(2000, 12, 30, 23, 59, 59),
                                Config.data.clock.time.format || "hh:mm")
    }
    TextMetrics {
        id: dateMetrics
        font: dateBlock.font
        text: Qt.formatDateTime(new Date(2000, 12, 30),
                                Config.data.clock.date.format || "yyyy-MM-dd")
    }
    ColumnLayout {
        id: contentItem
        anchors.centerIn: parent
        width: Math.max(timeBlock.Layout.preferredWidth, dateBlock.Layout.preferredWidth)
        height: parent.height
        spacing: gapSize
        Text {
            id: timeBlock
            Layout.alignment: Qt.AlignHCenter
            Layout.preferredHeight: (root.size - gapSize) / 2
            Layout.preferredWidth: timeMetrics.advanceWidth
            text: Qt.formatDateTime(clock.date, Config.data.clock.time.format || "hh:mm")
            font.family: Config.data.clock.font.family || Config.data.theme.font.family
            font.pixelSize: baseFontSize * timeScale
            font.weight: Config.data.clock.font.weight
            color: Config.data.theme.colors.textMuted
            visible: Config.data.clock.time.enabled !== false
            verticalAlignment: Text.AlignVCenter
        }
        Text {
            id: dateBlock
            Layout.alignment: Qt.AlignHCenter
            Layout.preferredHeight: (root.size - gapSize) / 2
            Layout.preferredWidth: dateMetrics.advanceWidth
            text: Qt.formatDateTime(clock.date, Config.data.clock.date.format || "yyyy-MM-dd")
            font.family: Config.data.clock.font.family || Config.data.theme.font.family
            font.pixelSize: baseFontSize * dateScale
            font.weight: Config.data.clock.font.weight
            color: Config.data.theme.colors.textMuted
            visible: Config.data.clock.date.enabled !== false
            verticalAlignment: Text.AlignVCenter
        }
    }
    readonly property real baseFontSize: {
        (timeBlock.visible && dateBlock.visible ? 0.5 : 1)
            * size * Config.data.clock.font.scale
    }
    readonly property real maxBlockHeight: size - gapSize
    readonly property real gapSize: size * 0.1
    property real timeScale: 1
    property real dateScale: 1
    Component.onCompleted: {
        if (!timeBlock.visible || !dateBlock.visible) return;
        const timeWidth = timeBlock.contentWidth;
        const dateWidth = dateBlock.contentWidth;
        // Give narrower block a boost
        let targetTimeScale = dateWidth > timeWidth ? 1.3 : 1;
        let targetDateScale = timeWidth > dateWidth ? 1.3 : 1;
        timeScale = targetTimeScale;
        dateScale = targetDateScale;
        // Scale down if either block is too tall
        if (timeBlock.contentHeight > maxBlockHeight) {
            timeScale *= maxBlockHeight / timeBlock.contentHeight;
        }
        if (dateBlock.contentHeight > maxBlockHeight) {
            dateScale *= maxBlockHeight / dateBlock.contentHeight;
        }
        // Ensure scaled block doesn't exceed the widest block's width
        const maxWidth = Math.max(timeWidth, dateWidth);
        if (timeBlock.contentWidth > maxWidth) {
            timeScale *= maxWidth / timeBlock.contentWidth;
        }
        if (dateBlock.contentWidth > maxWidth) {
            dateScale *= maxWidth / dateBlock.contentWidth;
        }
    }
}

import QtQuick
import QtQuick.Layouts
import Quickshell
import qs.modules.common
import qs.modules.common.utils
import qs.modules.common.widgets
import qs.modules.icons
import qs.services
Item {
    id: root
    property real scale: Config.data.cpu.scale || 1.0
    property real history: Config.data.cpu.graph.history || 60  // Seconds
    property real updateInterval: Config.data.cpu.updateInterval || 1000  // Milliseconds
    property color lineColor: Config.data.cpu.graph.lineColor
    property color lowUsageColor: Config.data.cpu.graph.lowUsageColor
    property color highUsageColor: Config.data.cpu.graph.highUsageColor
    readonly property color mixedUsageColor: ColorUtils.mix(lowUsageColor, highUsageColor)
    implicitWidth: (icon.visible ? icon.width : 0)
        + (graph.visible ? graph.width : 0) + 4
    implicitHeight: Config.data.bar.size - Config.data.bar.size * 0.2
    // Buffer for graph points (rolling window)
    property var points: []
    // Initial dummy point to avoid empty graph
    Component.onCompleted: {
        if (!graph.visible) return;
        points.push({ x: Date.now(), y: 0.0 });
        graph.requestPaint();
    }
    Timer {
        interval: updateInterval
        running: Config.data.cpu.graph.enabled
        repeat: true
        onTriggered: updateGraph()
    }
    function updateGraph() {
        // Add new point
        let x = Date.now();
        let y = CPU.overallUsage;
        points.push({ x: x, y: y });
        // Clean old points beyond history
        let cutoff = Date.now() - history * 1000;
        while (points.length > 0 && points[0].x < cutoff) {
            points.splice(0, 1);
        }
        graph.requestPaint();
    }
    CPUIcon {
        id: icon
        visible: Config.data.cpu.icon.enabled
        color: Config.data.cpu.icon.color
        scale: Config.data.cpu.icon.scale * root.height
        anchors.verticalCenter: parent.verticalCenter
    }
    Canvas {
        id: graph
        visible: Config.data.cpu.graph.enabled
        anchors {
            top: parent.top
            bottom: parent.bottom
            right: parent.right
        }
        width: 100 * root.scale
        onPaint: {
            let ctx = getContext("2d");
            ctx.clearRect(0, 0, width, height);
            let range = history * 1000;
            let currentTime = Date.now();
            let minTime = currentTime - range;
            let visiblePoints = points.filter(function(p) { return p.x >= minTime; });
            if (visiblePoints.length < 2) return;
            // Margin to avoid graph cutoff at top/bottom
            let margin = 2;
            let effectiveHeight = height - 2 * margin;
            ctx.strokeStyle = lineColor;
            ctx.lineWidth = 2;
            let gradient = ctx.createLinearGradient(0, height, 0, 0);  // Vertical from bottom to top
            gradient.addColorStop(0, lowUsageColor);
            gradient.addColorStop(0.5, mixedUsageColor);
            gradient.addColorStop(0.9, highUsageColor);
            ctx.fillStyle = gradient;
            // Draw fill under the line first (closed path)
            ctx.beginPath();
            ctx.moveTo(0, height+10);  // Start bottom-left
            for (let i = 0; i < visiblePoints.length; ++i) {
                let px = ((visiblePoints[i].x - minTime) / range) * width;
                let py = margin + (1 - visiblePoints[i].y) * effectiveHeight;
                if (i === 0) ctx.lineTo(px, py);
                ctx.lineTo(px, py);
            }
            ctx.lineTo(width, height);  // Bottom-right
            ctx.closePath();
            ctx.fill();
            // Draw stroke on top of the line (separate path)
            ctx.beginPath();
            for (let i = 0; i < visiblePoints.length; ++i) {
                let px = ((visiblePoints[i].x - minTime) / range) * width;
                let py = margin + (1 - visiblePoints[i].y) * effectiveHeight;
                if (i === 0) ctx.moveTo(px, py);
                ctx.lineTo(px, py);
            }
            ctx.stroke();
        }
    }
    HoverPopup {
        anchors.centerIn: root
        hoverTarget: root
        anchorPosition: Types.stringToPosition(Config.data.bar.position)
        contentComponent: Component {
            ColumnLayout {
                id: contentColumn
                spacing: 2
                Text {
                    Layout.alignment: Qt.AlignHCenter
                    text: "Load Average"
                    font.family: Config.data.theme.font.family
                    font.pixelSize: Config.data.theme.font.size
                    font.bold: true
                    color: Config.data.theme.colors.foreground
                }
                Text {
                    Layout.alignment: Qt.AlignHCenter
                    font.family: Config.data.theme.fontMono.family
                    font.pixelSize: Config.data.theme.fontMono.size
                    color: Config.data.theme.colors.foreground
                    text: {
                        let names = ['1m', '5m', '15m'];
                        let out = [];
                        for (let i = 0; i < CPU.loadAvg.length; ++i) {
                            let name = `${names[i]}:`.padStart(5).padEnd(6);
                            let val = CPU.loadAvg[i].toFixed(2);
                            out.push(`${name}${val}`);
                        }
                        return out.join("\n")
                    }
                }
                Text {
                    Layout.alignment: Qt.AlignHCenter
                    text: "CPU Core Usage"
                    font.family: Config.data.theme.font.family
                    font.pixelSize: Config.data.theme.font.size
                    font.bold: true
                    color: Config.data.theme.colors.foreground
                    Layout.topMargin: 6
                }
                Text {
                    Layout.alignment: Qt.AlignHCenter
                    font.family: Config.data.theme.fontMono.family
                    font.pixelSize: Config.data.theme.fontMono.size
                    color: Config.data.theme.colors.foreground
                    text: {
                        let out = [];
                        for (let i = 0; i < CPU.coreUsages.length; ++i) {
                            let coreNum = `Core ${i+1}:`.padEnd(10);
                            let coreUsage = CPU.coreUsages[i].toFixed(2);
                            out.push(`${coreNum}${coreUsage}`);
                        }
                        return out.join("\n");
                    }
                }
                Text {
                    Layout.alignment: Qt.AlignHCenter
                    text: "Top Processes"
                    font.family: Config.data.theme.font.family
                    font.pixelSize: Config.data.theme.font.size
                    font.bold: true
                    color: Config.data.theme.colors.foreground
                    Layout.topMargin: 6
                }
                Text {
                    Layout.alignment: Qt.AlignHCenter
                    font.family: Config.data.theme.fontMono.family
                    font.pixelSize: Config.data.theme.fontMono.size
                    color: Config.data.theme.colors.foreground
                    text: {
                        let out = [];
                        for (let p of CPU.topProcesses) {
                            let pidStr = p.pid.toString().padStart(6);
                            let commStr = p.comm.slice(0, 15).padEnd(15);
                            let cpuStr = `${p.cpu.toFixed(1)}%`;
                            out.push(`${pidStr} ${commStr}\t${cpuStr.padStart(6)}`);
                        }
                        return out.join("\n");
                    }
                }
            }
        }
    }
}

import QtQuick
import QtQuick.Layouts
import Qt5Compat.GraphicalEffects
import Quickshell
import Quickshell.Services.UPower
import qs.modules.common
import qs.modules.common.widgets
import qs.modules.icons
import qs.services
Item {
    id: root
    property int orientation: Types.Orientation.Horizontal
    readonly property var chargeState: Battery.chargeState
    readonly property bool isCharging: Battery.isCharging
    readonly property bool isPluggedIn: Battery.isPluggedIn
    readonly property real percentage: Battery.percentage
    readonly property bool isLow: percentage <= Config.data.battery.low / 100
    readonly property bool isCritical: percentage <= Config.data.battery.critical / 100
    implicitWidth: icon.width
    implicitHeight: icon.height
    ProgressBarText {
        id: batteryProgress
        anchors {
            left: icon.left
            bottom: icon.bottom
        }
        valueBarWidth: icon.bodyWidth
        valueBarHeight: icon.bodyHeight
        value: percentage
        text: Config.data.battery.showPercentage ? Math.round(value * 100) : ""
        orientation: root.orientation
        shimmer: isCharging
        pulse: isCharging
        highlightColor: (() => {
            if (isCritical && !isCharging) {
                return Config.data.theme.colors.error;
            }
            if (isLow && !isCharging) {
                return Config.data.theme.colors.warning;
            }
            return Config.data.theme.colors.ok;
        })()
        font.family: "Noto Sans"
        font.bold: true
        font.pixelSize: Config.data.theme.font.size * Config.data.battery.scale * 0.7
        textColor: Config.data.theme.colors.foreground
        // Clip the progress bar within the borders of the battery icon body
        layer.enabled: true
        layer.effect: OpacityMask {
            maskSource: Item {
                width: batteryProgress.width
                height: batteryProgress.height
                Rectangle {
                    x: icon.borderWidth
                    y: icon.borderWidth
                    width: icon.bodyWidth - icon.borderWidth * 2
                    height: icon.bodyHeight - icon.borderWidth * 2
                    radius: icon.bodyRadius / 2
                }
            }
        }
    }
    BatteryIcon {
        id: icon
        anchors.centerIn: parent
        size: Math.min(Config.data.battery.scale * Config.data.theme.widget.size,
                       Config.data.bar.size)
        iconColor: Config.data.theme.colors.foreground
        orientation: root.orientation
    }
    HoverPopup {
        anchors.centerIn: icon
        hoverTarget: icon
        anchorPosition: Types.stringToPosition(Config.data.bar.position)
        contentComponent: Component {
            ColumnLayout {
                id: contentColumn
                spacing: 4
                Text {
                    text: {
                        if (Battery.energyRate > 0) {
                            const status = (() => {
                                if (Battery.isCharging) return "Charging";
                                if (Battery.chargeState == UPowerDeviceState.Discharging) return "Discharging";
                                return "Unknown";
                            })();
                            return status + ": " + Battery.energyRate.toFixed(1) + "W";
                        } else {
                            const state = Battery.chargeState;
                            if (state == UPowerDeviceState.FullyCharged) return "Fully charged";
                            if (state == UPowerDeviceState.PendingCharge) return "Plugged in (not charging)";
                            if (state == UPowerDeviceState.Discharging) return "On battery";
                            return "Unknown";
                        }
                    }
                    color: Config.data.theme.colors.foreground
                    font.family: Config.data.theme.font.family
                    font.pixelSize: Config.data.theme.font.size
                }
                Text {
                    text: {
                        if (Battery.isCharging) {
                            const hours = Math.floor(Battery.timeToFull / 3600);
                            const minutes = Math.floor((Battery.timeToFull % 3600) / 60);
                            return "Time to full: " + hours + "h " + minutes + "m";
                        } else {
                            const hours = Math.floor(Battery.timeToEmpty / 3600);
                            const minutes = Math.floor((Battery.timeToEmpty % 3600) / 60);
                            return "Time remaining: " + hours + "h " + minutes + "m";
                        }
                    }
                    color: Config.data.theme.colors.foreground
                    font.family: Config.data.theme.font.family
                    font.pixelSize: Config.data.theme.font.size
                    visible: Battery.energyRate > 0 && ((Battery.isCharging && Battery.timeToFull > 0) || (!Battery.isCharging && Battery.timeToEmpty > 0))
                }
            }
        }
    }
}

import QtQuick
import QtQuick.Effects
import QtQuick.Layouts
import Quickshell
import Quickshell.Wayland
import qs.modules.common
import qs.modules.common.utils
import qs.modules.icons
Item {
    id: root
    property int position: Types.Position.Top
    property string color: "gray"
    property int size: 30
    WlrLayershell {
        id: barShadow
        implicitHeight: bar.height + 100
        color: "transparent"
        layer: WlrLayer.Bottom
        exclusionMode: ExclusionMode.Ignore
        anchors: bar.anchors
        Rectangle {
            color: barContent.color
            anchors {
                top: root.position === Types.Position.Top ? parent.top : undefined
                bottom: root.position === Types.Position.Bottom ? parent.bottom : undefined
            }
            height: barContent.height
            // The +40 here and the -20 shadowHorizontalOffset are to have the
            // shadow extend all the way along the edge. Otherwise it would be
            // slightly cut off at the left and right corners.
            width: parent.width + 40
            layer.enabled: true
            layer.effect: MultiEffect {
                shadowEnabled: true
                // The vertical offset makes the shadow slightly more prominent
                shadowVerticalOffset: root.position === Types.Position.Top ? 5 : -5
                shadowHorizontalOffset: -20
                shadowBlur: 1
                blurMultiplier: 1
                shadowColor: "#D0000000"
            }
        }
    }
    PanelWindow {
        id: bar
        implicitHeight: root.size
        color: "transparent"
        anchors {
            top: root.position === Types.Position.Top
            bottom: root.position === Types.Position.Bottom
            left: true
            right: true
        }
        // Widget component definitions
        Component {
            id: separatorComponent
            SeparatorIcon {
                color: ColorUtils.transparentize(Config.data.theme.colors.foreground2, 0.5)
                angle: 90
                length: bar.height - bar.height * 0.4
                strokeSize: 4
                spacing: 1.5
                lineType: "dotted"
                dashLength: 1
                edgeRadius: 4
                Layout.alignment: Qt.AlignVCenter
            }
        }
        Component { id: workspacesComponent; Workspaces {} }
        Component { id: focusedWindowComponent; FocusedWindow {} }
        Component { id: cpuComponent; CPU {} }
        Component { id: ramComponent; RAM {} }
        Component { id: networkComponent; Network {} }
        Component {
            id: batteryComponent
            Battery {
                orientation: Types.stringToOrientation(Config.data.battery.orientation)
            }
        }
        Component {
            id: clockComponent
            Clock {
                size: Math.min(
                    root.size * Config.data.clock.scale - root.size * 0.2,
                    root.size,
                )
            }
        }
        readonly property var widgetComponents: {
            "battery": batteryComponent,
            "clock": clockComponent,
            "cpu": cpuComponent,
            "focusedWindow": focusedWindowComponent,
            "network": networkComponent,
            "ram": ramComponent,
            "separator": separatorComponent,
            "workspaces": workspacesComponent,
        }
        Rectangle {
            id: barContent
            anchors.fill: parent
            color: root.color
            LayoutSection {
                section: "left"
                widgetComponents: bar.widgetComponents
                anchors {
                    verticalCenter: parent.verticalCenter
                    left: parent.left
                    leftMargin: 6
                }
            }
            LayoutSection {
                section: "center"
                widgetComponents: bar.widgetComponents
                anchors {
                    horizontalCenter: parent.horizontalCenter
                    verticalCenter: parent.verticalCenter
                }
            }
            LayoutSection {
                section: "right"
                widgetComponents: bar.widgetComponents
                anchors {
                    verticalCenter: parent.verticalCenter
                    right: parent.right
                    rightMargin: 6
                }
            }
        }
    }
}

      quickshell

  inputs.quickshell = {
    url = "git+https://git.outfoxxed.me/outfoxxed/quickshell";

    inputs.nixpkgs.follows = "os";
  };
  inputs.qml-niri = {
    url = "github:imiric/qml-niri/main";
    inputs.nixpkgs.follows = "os";
    inputs.quickshell.follows = "quickshell";
  };

    "flake-parts": {
      "inputs": {
        "nixpkgs-lib": "nixpkgs-lib"
      },
      "locked": {
        "lastModified": 1762040540,
        "narHash": "sha256-z5PlZ47j50VNF3R+IMS9LmzI5fYRGY/Z5O5tol1c9I4=",
        "owner": "hercules-ci",
        "repo": "flake-parts",
        "rev": "0010412d62a25d959151790968765a70c436598b",
        "type": "github"
      },
      "original": {
        "owner": "hercules-ci",
        "repo": "flake-parts",
        "type": "github"
      }
    },

        "type": "github"
      }
    },
    "nixpkgs": {
      "locked": {
        "lastModified": 1761236834,
        "narHash": "sha256-+pthv6hrL5VLW2UqPdISGuLiUZ6SnAXdd2DdUE+fV2Q=",
        "owner": "nixos",
        "repo": "nixpkgs",
        "rev": "d5faa84122bc0a1fd5d378492efce4e289f8eac1",
        "type": "github"
      },
      "original": {
        "owner": "nixos",
        "ref": "nixpkgs-unstable",
        "repo": "nixpkgs",

    "nixpkgs-lib": {
      "locked": {
        "lastModified": 1761765539,
        "narHash": "sha256-b0yj6kfvO8ApcSE+QmA6mUfu8IYG6/uU28OFn4PaC8M=",
        "owner": "nix-community",
        "repo": "nixpkgs.lib",
        "rev": "719359f4562934ae99f5443f20aa06c2ffff91fc",
        "type": "github"
      },
      "original": {
        "owner": "nix-community",
        "repo": "nixpkgs.lib",
        "type": "github"
      }
    },

    "qml-niri": {
      "inputs": {
        "flake-parts": "flake-parts",
        "nixpkgs": [
          "os"
        ],
        "quickshell": [
          "quickshell"
        ],
        "treefmt-nix": "treefmt-nix_2"
      },
      "locked": {
        "lastModified": 1766224085,
        "narHash": "sha256-hZbaqww++6dh2324Us3h868BZWDAzZViiB4c6/i/BDo=",
        "owner": "imiric",
        "repo": "qml-niri",
        "rev": "39e9c83d908318032ccd5330b1ad77764b498eb8",
        "type": "github"
      },
      "original": {
        "owner": "imiric",
        "ref": "main",
        "repo": "qml-niri",
        "type": "github"
      }
    },
    "quickshell": {
      "inputs": {
        "nixpkgs": [
          "os"
        ]
      },
      "locked": {
        "lastModified": 1768549203,
        "narHash": "sha256-DxN7v8g8DO8gGJmgBJMo3fsSR3HEs+DFCXeKeHq61zA=",
        "ref": "refs/heads/master",
        "rev": "d03c59768c680f052dff6e7a7918bbf990b0f743",
        "revCount": 727,
        "type": "git",
        "url": "https://git.outfoxxed.me/outfoxxed/quickshell"
      },
      "original": {
        "type": "git",
        "url": "https://git.outfoxxed.me/outfoxxed/quickshell"
      }
    },

        "qml-niri": "qml-niri",
        "quickshell": "quickshell",

        "type": "github"
      },
      "original": {
        "owner": "numtide",
        "repo": "treefmt-nix",
        "type": "github"
      }
    },
    "treefmt-nix_2": {
      "inputs": {
        "nixpkgs": "nixpkgs"
      },
      "locked": {
        "lastModified": 1762410071,
        "narHash": "sha256-aF5fvoZeoXNPxT0bejFUBXeUjXfHLSL7g+mjR/p5TEg=",
        "owner": "numtide",
        "repo": "treefmt-nix",
        "rev": "97a30861b13c3731a84e09405414398fbf3e109f",