{ lib, inputs, ... }:
let
  inherit (lib) const;
  # Extend nixpkgs.lib with nix-darwin.lib, then our custom lib.
  lib' = inputs.os.lib.extend (const <| const <| inputs.os-darwin.lib);
  libCustom = lib'.extend <| import ../lib inputs;
in
{
  # Add yuzu-dendritic to the flake outputs
  config.flake.nixosConfigurations.yuzu-dendritic =
    libCustom.mkNixos "x86_64-linux" "yuzu-dendritic";
}

{ inputs, lib, ... }:
let
  inherit (builtins) pathExists readDir;
  inherit (lib)
    filterAttrs
    hasSuffix
    mapAttrs'
    nameValuePair
    removeSuffix
    ;
  newHostsDir = ../new-hosts;
  hasNewHosts = pathExists newHostsDir;
  # Read all .host.nix files from new-hosts directory
  newHostsFiles =
    if hasNewHosts
    then
      readDir newHostsDir
      |> filterAttrs (name: type: type == "regular" && hasSuffix ".host.nix" name)
      |> mapAttrs' (
        name: _value:
          nameValuePair (removeSuffix ".host.nix" name) (import (newHostsDir + "/${name}") { inherit lib inputs; })
      )
    else { };
in
{
  # Each .host.nix file should return a flake-parts module that sets config.flake.*
  imports = builtins.attrValues newHostsFiles;
}

{ lib, ... }:
{
  options.flake.modules = lib.mkOption {
    type = lib.types.attrsOf (lib.types.attrsOf lib.types.deferredModule);
    default = { };
  };
}

{ lib, ... }:

{ inputs, ... }:
{
  imports = [ inputs.parts.flakeModules.modules ];
}